groovy 中的 grep 命令用法

Question

How to write the below shell in groovy

process_name = spin_user

if grep -i ${process_name} /tmp/output.log ; then 
  echo "Success" 
  grep -i ${process_name} output.log > final_output.log 
else 
  echo "failure" 
fi 

Answer 1

<< edited in response to comment >>

1. Pure Groovy Solution

If you just want to implement the functionality in your bash script in groovy, you can do something like this:

def processName = 'spin_user'
def outLog      = new File('/tmp/output.log')
def finalLog    = new File('final_output.log')

def lines       = outLog.readLines()
def hasProcess  = { it.toLowerCase().contains(processName) }

if(lines.any(hasProcess)) { 
  println "Sucess"
  finalLog.text = lines.findAll(hasProcess).join('\n')
} else { 
  println "failure"
}

should be noted that if your log file is large, there are better ways of searching for a string that do not require you to load the entire file into memory.

2. Process Management Solution

If you were specifically looking to use the linux system grep command from within groovy, the above will naturally not help you. The following groovy code:

import java.util.concurrent.*

def processName = 'spin_user'
def outLog      = '/tmp/output.log'
def finalLog    = 'final_output.log'

def result = exec('grep', '-i', processName, outLog)
if (result) {
  println "success"
  new File(finalLog).text = result
} else { 
  println "failure"
}

String exec(String... args) {
  def out = new StringBuffer()
  def err = new StringBuffer()

  def process = args.toList().execute()

  process.consumeProcessOutput(out, err)
  process.waitForOrKill(5000)

  if (err) {
    println "ERROR:  executing ${args} returned ${process.exitValue()}"
    println "STDERR: ${err}"
  }

  out
}

will execute the grep command and should get you closer to what you want.

It should be noted that the output redirection > in your shell command is as far as I know hard to do on an external process from java/groovy and we are therefore writing the output to the final_output.log file from within groovy instead of executing the command using output redirection.

I also added a five second max timeout on the grep process execution. This is not required and that line can safely be removed, it's just there as a safeguard for cases where the grep blocks indefinitely.