检查单元格是否包含“特定单词”然后删除行

Question

I tried the code but it still unable to delete the cells which contains DNP. Is there something wrong with the code? Thank you

'Check to see if column contains dnp then delete row

Last = wsInput.Range("H" & Rows.Count).End(xlUp).Row
For iCntr = Last To 3 Step -1
If InStr(1, wsInput.Cells(iCntr, "H"), "dnp", vbTextCompare) = "[dnp]"Then 

         wsInput.Cells(iCntr, "H").EntireRow.Delete
    End If
Next iCntr

Answer 1

Create a range then do 1 delete, much better than multiple deletes.

Sub Temp()
Dim DelRange As Range, iCntr  as Long
For iCntr = 3 to Range("H" & Rows.Count).End(xlUp).Row
    If InStr(1, Range("H" & iCntr).Text, "dnp", vbTextCompare) > 0 Then
        If DelRange Is Nothing Then
            Set DelRange = Range("H" & iCntr)
        Else
            Set DelRange = Union(DelRange, Range("H" & iCntr))
        End If
    End If
Next iCntr
If Not DelRange Is Nothing Then DelRange.EntireRow.Delete
End Sub

The reason yours wasn't working is because Instr returns a numeric showing the position in the first string that the second string was found. If it finds the string it will return something >0 if it doesn't it will return 0

If you want to do it without looping the range (which will be faster) you can use Find like this:

Sub temp2()
Dim FoundCell As Range, LastCell As Range, DelRange As Range, FirstAddr As String
Set LastCell = Range("H" & Rows.Count)
Set FoundCell = Range("H:H").Find(what:="dnp", after:=LastCell)
Set DelRange = FoundCell
If Not FoundCell Is Nothing Then FirstAddr = FoundCell.Address
Do Until FoundCell Is Nothing
    Set FoundCell = Range("H:H").FindNext(after:=FoundCell)
    Set DelRange = Union(DelRange, FoundCell)
    If FoundCell.Address = FirstAddr Then Exit Do
Loop
If Not DelRange Is Nothing Then DelRange.EntireRow.Delete
End Sub