如何删除用户指定行中的特定单元格

Question

I am looking for help to delete specific cells in a row that is specified by the user ( activecell.row ). My code inserts a line below the currently selected row. I would also like to delete a couple of the cells in that row without deleting the entire row and all of the formulas.

Sub AddNewLine()
    Dim ws As Worksheet
    Dim rng As Range
    Dim myVal As Integer

    ActiveSheet.Unprotect
    
    '~~> Set this to the relevant worksheet
    Set ws = ActiveWorkbook.ActiveSheet

    With ws
        '~~> Set your range
        Set rng = .Rows(ActiveCell.Row)

        '~~> Copy the range
        rng.Copy

        '~~> Insert the range
        rng.Offset(1).Insert Shift:=xlDown
   
        'I would like to delete the values in these cells:
            Range("G.25").ClearContents
            Range("I25").ClearContents
            Range("J25").ClearContents
            Range("K25").ClearContents

    End With
       
    ActiveSheet.Protect
    
End Sub

Thanks for your help!

Answer 1

Try this code:

Sub AddNewLine()
    Dim ws As Worksheet
    Dim rng As Range
    Dim myVal As Integer

    ActiveSheet.Unprotect
    
    '~~> Set this to the relevant worksheet
    Set ws = ActiveWorkbook.ActiveSheet

    With ws
        '~~> Set your range
        Set rng = .Rows(ActiveCell.Row)

        '~~> Copy the range
        rng.Copy

        '~~> Insert the range
        rng.Offset(1).Insert Shift:=xlDown
   
        'I would like to delete the values in these cells:
        rng.Offset(1).Columns("G").ClearContents
        rng.Offset(1).Columns("I:K").ClearContents

    End With
       
    ActiveSheet.Protect
    
End Sub

Answer 2

Sub AddNewLine()
    Dim rng As Range
    
    With ActiveSheet
        .Unprotect
    
        '~~> Set your range
        Set rng = ActiveCell.EntireRow
        
        '~~> Copy the range
        rng.Copy
        
        '~~> Insert the range
        rng.Offset(1).Insert
        
        'I would like to delete the values in these cells:
        Intersect(.Range("G:G, I:K"), rng).ClearContents
    
        .Protect
    End With
End Sub