在XSLT 1.0中使用定时逻辑的JSON输出

Question

I'm trying to read messages in a XML and output as JSON. Each message also has a timing logic to show and hide the message.

Below is my XML with each message having start and end date/time

<activeMessage>
<message>
<messageText>test message 1</messageText>
<displayScheduleContainer>
<startDate>17/05/2019</startDate>
<startTimeHrs>12</startTimeHrs>
<startTimeMins>00</startTimeMins>
<noEndDate/>
<endDate>17/05/2019</endDate>
<endTimeHrs>23</endTimeHrs>
<endTimeMins>59</endTimeMins>
</displayScheduleContainer>
</message>  

Below is my XSL

<xsl:for-each select="xalan:nodeset($messageData)/activeMessage/message">

                    <xsl:variable name="messageInDateTime">
                        <xsl:call-template name="dateLessThanTemplate">
                            <xsl:with-param name="startDateTime" select="concat(displayScheduleContainer/startDate, ' ', displayScheduleContainer/startTimeHrs, ':', displayScheduleContainer/startTimeMins)" />
                            <xsl:with-param name="endDateTime" select="concat(displayScheduleContainer/endDate, ' ', displayScheduleContainer/endTimeHrs, ':', displayScheduleContainer/endTimeMins)" />
                        </xsl:call-template>
                    </xsl:variable>

                    <xsl:if test="$messageInDateTime = 'true'">
                        <xsl:choose>
                            <xsl:when test="position()=1">
                                <xsl:call-template name="singleMessageJSON" />
                            </xsl:when>
                            <xsl:otherwise>
                                <xsl:call-template name="multiMessageJSON" />
                            </xsl:otherwise>
                        </xsl:choose>
                    </xsl:if>
        </xsl:for-each>

Answer 1

As you have added the tag for XSLT 3 I think you can get rid of any Java call and simply use eg

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:mf="http://example.com/mf"
    exclude-result-prefixes="#all"
    version="3.0">

  <xsl:function name="mf:get-dateTime" as="xs:dateTime?">
      <xsl:param name="date" as="xs:string"/>
      <xsl:param name="hours" as="xs:string"/>
      <xsl:param name="minutes" as="xs:string"/>
      <xsl:try 
        select="xs:dateTime(replace($date, '([0-9]{2})/([0-9]{2})/([0-9]{4})', '$3-$2-$1') || 'T' || $hours || ':' || $minutes || ':00')">
          <xsl:catch select="()"/>
      </xsl:try>
  </xsl:function>

  <xsl:param name="now" select="current-dateTime()"/>
  <xsl:output method="json" indent="yes"/>

  <xsl:template match="activeMessage">
      <xsl:sequence
        select="map { 
          'message' : array { 
            message[mf:get-dateTime(displayScheduleContainer/startDate, displayScheduleContainer/startTimeHrs, displayScheduleContainer/startTimeMins) lt $now
                    and 
                    mf:get-dateTime(displayScheduleContainer/endDate, displayScheduleContainer/endTimeHrs, displayScheduleContainer/endTimeMins) gt $now]/messageText[normalize-space()]/string() 
            }
          }"/>
  </xsl:template>

</xsl:stylesheet>

in XSLT 3 with Saxon 9.8 or later. I am not sure about the exact JSON output format you want but the main advantage of XSLT 3 is that you can construct maps and arrays in XSLT/XPath and they get serialized as JSON if needed without having to worry about outputting commas in the right place.

https://xsltfiddle.liberty-development.net/bnnZWx/1

It would probably be better to move the two comparisons of the dates into another function as that predicate then becomes more readable:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:mf="http://example.com/mf"
    exclude-result-prefixes="#all"
    version="3.0">

  <xsl:function name="mf:get-dateTime" as="xs:dateTime?">
      <xsl:param name="date" as="xs:string"/>
      <xsl:param name="hours" as="xs:string"/>
      <xsl:param name="minutes" as="xs:string"/>
      <xsl:try 
        select="xs:dateTime(replace($date, '([0-9]{2})/([0-9]{2})/([0-9]{4})', '$3-$2-$1') || 'T' || $hours || ':' || $minutes || ':00')">
          <xsl:catch select="()"/>
      </xsl:try>
  </xsl:function>

  <xsl:function name="mf:compare-dates" as="xs:boolean">
      <xsl:param name="schedule" as="element(displayScheduleContainer)"/>
      <xsl:sequence
        select="mf:get-dateTime($schedule/startDate, $schedule/startTimeHrs, $schedule/startTimeMins) lt $now
                and 
                mf:get-dateTime($schedule/endDate, $schedule/endTimeHrs, $schedule/endTimeMins) gt $now"/>
  </xsl:function>

  <xsl:param name="now" select="current-dateTime()"/>
  <xsl:output method="json" indent="yes"/>

  <xsl:template match="activeMessage">
      <xsl:sequence
        select="map { 
          'message' : array { 
            message[mf:compare-dates(displayScheduleContainer)]/messageText[normalize-space()]/string() 
            }
          }"/>
  </xsl:template>

</xsl:stylesheet>

https://xsltfiddle.liberty-development.net/bnnZWx/2