XSLT 1.0逻辑分割元素

Question

The Loop-1,2 and 3 elements are unbounded.below is the input xml which has all the LOOP-1 elements comes first and then Loop-2 elements. how we can transform that into like output xml.I tried below xslt but it is giving as same input.

input xml:

<root>
<LOOP-1><!-- unbounded -->
<element1>A</element1>
</LOOP-1>
<LOOP-1>
<element1>A</element1>
</LOOP-1>

<LOOP-2><!-- unbounded -->
<element2>B</element2>
</LOOP-2>

<LOOP-2>
<element2>B</element2>
</LOOP-2>

</root>

XSLT:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output indent="yes"/>

<xsl:template match="/">
    <xsl:copy-of select="."/>
</xsl:template>

</xsl:stylesheet>

output:

<?xml version="1.0"?>
<root>
<LOOP-1> 
<element1>A</element1>
</LOOP-1>
<LOOP-2> 
<element2>B</element2>
</LOOP-2>
<LOOP-1>
<element1> A</element1>
</LOOP-1>
<LOOP-2>
<element2>B</element2>
</LOOP-2>
</root>

Answer 1

You can try the code below:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output indent="yes"/>

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="/root">
        <xsl:for-each select="child::LOOP-1">
            <xsl:variable name="pos" select="position()"/>
            <xsl:copy>
                <xsl:apply-templates/>
            </xsl:copy>
            <xsl:apply-templates select="following-sibling::LOOP-2[position()=$pos]"/>
        </xsl:for-each>
    </xsl:template>

</xsl:stylesheet>

Answer 2

If you want to cope with any number of LOOP elements (You mention 1,2 and 3 in the first sentence, but don't actually show 3 in your example), what you could do is define a key to help the looking up of the elements based on their 'number'.

<xsl:key name="loop" match="*[starts-with(local-name(), 'LOOP')]" use="substring-after(local-name(), '-')" />

You would then start off by selecting only the LOOP-1 elements

<xsl:apply-templates select="key('loop', '1')" />

Next, you would have a share template to match any LOOP element, regardless of number

Within this you would call the identity template to copy the element, followed by an apply-templates to select the LOOP element with the next number, but one in the same position:

 <xsl:apply-templates select="key('loop', string(number(substring-after(local-name(), '-')) + 1))[$pos]" />

Try this XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" omit-xml-declaration="yes" indent="yes" />

  <xsl:key name="loop" match="*[starts-with(local-name(), 'LOOP')]" use="substring-after(local-name(), '-')" />

  <xsl:template match="root">
    <root>
      <xsl:apply-templates select="key('loop', '1')" />
    </root>
  </xsl:template>

  <xsl:template match="*[starts-with(local-name(), 'LOOP')]">
     <xsl:call-template name="identity" />
     <xsl:variable name="pos" select="position()" />
     <xsl:apply-templates select="key('loop', string(number(substring-after(local-name(), '-')) + 1))[$pos]" />
  </xsl:template>

  <xsl:template match="@*|node()" name="identity">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>
</xsl:stylesheet>