XSLT 1.0邏輯分割元素

Question

Loop-1,2和3元素是無界的。下面是輸入xml，它具有所有LOOP-1元素，然后是Loop-2元素。 我們如何將其轉換成類似輸出的xml。我在xslt下嘗試過，但它提供了相同的輸入。

輸入xml：

<root>
<LOOP-1><!-- unbounded -->
<element1>A</element1>
</LOOP-1>
<LOOP-1>
<element1>A</element1>
</LOOP-1>

<LOOP-2><!-- unbounded -->
<element2>B</element2>
</LOOP-2>

<LOOP-2>
<element2>B</element2>
</LOOP-2>

</root>

XSLT：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output indent="yes"/>

<xsl:template match="/">
    <xsl:copy-of select="."/>
</xsl:template>

</xsl:stylesheet>

輸出：

<?xml version="1.0"?>
<root>
<LOOP-1> 
<element1>A</element1>
</LOOP-1>
<LOOP-2> 
<element2>B</element2>
</LOOP-2>
<LOOP-1>
<element1> A</element1>
</LOOP-1>
<LOOP-2>
<element2>B</element2>
</LOOP-2>
</root>

Answer 1

您可以嘗試以下代碼：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output indent="yes"/>

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="/root">
        <xsl:for-each select="child::LOOP-1">
            <xsl:variable name="pos" select="position()"/>
            <xsl:copy>
                <xsl:apply-templates/>
            </xsl:copy>
            <xsl:apply-templates select="following-sibling::LOOP-2[position()=$pos]"/>
        </xsl:for-each>
    </xsl:template>

</xsl:stylesheet>

Answer 2

如果要處理任何數量的LOOP元素（在第一句中提到了1,2和3，但在示例中並未實際顯示3），則可以做的是定義一個鍵來幫助查找基於其“數量”的元素。

<xsl:key name="loop" match="*[starts-with(local-name(), 'LOOP')]" use="substring-after(local-name(), '-')" />

然后，您將僅選擇LOOP-1元素

<xsl:apply-templates select="key('loop', '1')" />

接下來，您將擁有一個共享模板來匹配任何LOOP元素，無論數量如何

在此方法中，您將調用身份模板來復制元素，然后調用apply-templates選擇具有下一個數字但位置相同的LOOP元素：

 <xsl:apply-templates select="key('loop', string(number(substring-after(local-name(), '-')) + 1))[$pos]" />

試試這個XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" omit-xml-declaration="yes" indent="yes" />

  <xsl:key name="loop" match="*[starts-with(local-name(), 'LOOP')]" use="substring-after(local-name(), '-')" />

  <xsl:template match="root">
    <root>
      <xsl:apply-templates select="key('loop', '1')" />
    </root>
  </xsl:template>

  <xsl:template match="*[starts-with(local-name(), 'LOOP')]">
     <xsl:call-template name="identity" />
     <xsl:variable name="pos" select="position()" />
     <xsl:apply-templates select="key('loop', string(number(substring-after(local-name(), '-')) + 1))[$pos]" />
  </xsl:template>

  <xsl:template match="@*|node()" name="identity">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>
</xsl:stylesheet>