如何根据列的值粘贴到一行

Question

It may be already on here and Ive missed it but I'm having trouble working out how to change my code from pasting into the last row to pasting into a specific row.

Each dataset has a unique number in column A. I need to paste the Array into the row which matches the unique reference on the data entry Sheet.

So if the data entry sheet (Enter Action), has "123" in cell C3, I need it to look at the database (RAW DATA) and find the row with "123" in Column A and paste the Array into this row.

I have only ever pasted into the last row before and don't know how to change the below code to do what I need.

Dim vCopy, i As Long, rPaste As Range
vCopy = Array("C3", "C5", "Q26", "C7", "C9", "Q26", "C11", "C13", "C15", "G13", "G3", "C17", "G7", "G9", "K3", "G11", "K9")

Set rPaste = Sheets("RAW DATA").Cells(Rows.count, 1).End(xlUp)(2)

For i = LBound(vCopy) To UBound(vCopy)
  rPaste.Value = Sheets("Enter Action").Range(vCopy(i)).Value
  Set rPaste = rPaste.Offset(, 1)
 Next i

Answer 1

You can use Find :

Dim vCopy, i As Long, f As Range, lookFor

vCopy = Array("C3", "C5", "Q26", "C7", "C9", "Q26", "C11", "C13", "C15", _
              "G13", "G3", "C17", "G7", "G9", "K3", "G11", "K9")

lookFor = Sheets("Enter Action").range("c3").value
Set f = Sheets("RAW DATA").Columns(1).find(lookFor, lookat:=xlWhole)

If not f is nothing then
    For i = LBound(vCopy) To UBound(vCopy)
        f.Offset(0, i).Value = Sheets("Enter Action").Range(vCopy(i)).Value 'fixed#2
    Next i
End If