尝试使用Bat文件获取目录和子目录中所有文件的行数

Question

I am trying to get this bat file i am working on to provide me with a list of documents in a directory (and all of the sub-directories) and the line counts per document.

I have been able to get the code below to work but it only provides me the documents in the root of the folder, none of the sub-directories. I've searched so many different forums but have been unable to find a workable answer.

@echo off

:start
cls
echo Enter full path to directory that you want to count files for:
set /P FilePath=
echo ..
echo ...
if exist %FilePath%\CountLines.csv del %FilePath%\CountLines.csv /q
for /f "usebackq delims=" %%a in (`find /v /c "" "%FilePath%"\*.*`) do echo %%a >> "%FilePath%"\CountLines.csv
pause()
goto start

This is the output i get, which is correct but its not returning docs in the sub-directories

MD5HASH APPEARS ONCE.csv 1174690 
Split.txt 4258 
COUNTLINESINFILES.txt 1 

Answer 1

@echo off
setlocal

echo Enter full path to directory that you want to count files for:

rem Get path of the directory to search.
set /P "FilePath=" || (
    >&2 echo Invalid reply.
    exit /b 1
)

rem Check if the dir path exists.
if not exist "%FilePath%\" (
    >&2 echo Invalid path.
    exit /b 1
)

echo ..
echo ...

rem Get count of lines of files in the dir path.
(
    for /r "%FilePath%" %%A in (*) do (
        find /v /c "" "%%~A"
    )
) > "%FilePath%\CountLines.csv"

echo Results:
type "%FilePath%\CountLines.csv"
pause

If setting variables in a script, setlocal can help to keep the variables local to the script. setlocal has been added.

Consider that if the user presses return , without entering anything, then that can be a invalid path else a path starting with a single backslash can be interpreted as from the root of a drive. I do not consider the user may consider that so the || is a failure check, and executes the parenthesed code if it is a failure.

Check if the replied path is valid before continuing.

The for /r loop will iterate recursively with the pattern of * . find will read each file and the stdout is written to file. With the whole for /r within parentheses, allows all stdout to be written to file before closing the file handle.

The results are shown at the end by using type .

See for /? for help with understanding for /r and all the other types of for loops.