根据单元格值更改标签颜色

Question

I have an Excel workbook with multiple tabs, most contain project information with a specific cell for reporting the project status. I have tried pulling together a macro to set the tab colors according to the project status (for easier identification). There are some tabs in the workbook that don't contain this project status cell which I've tried to exclude from the routine.

Sub Set_tab_color()
    Dim WS As Worksheet
    For Each WS In ActiveWorkbook.Worksheets

    If Not WS.Name = "Cover" _
    And Not WS.Name = "Due Dill" _
    And Not WS.Name = "Comm '19" _
    And Not WS.Name = "Comm '18" _
    And Not WS.Name = "Comm '17" _
    And Not WS.Name = "Clarizen_PLI" _
    And Not WS.Name = "Clarizen_milestones" _
    And Not WS.Name = "_blank" Then
    End If

        Select Case WS.Range("B5").Value
        Case "C"
            WS.Tab.Color = RGB(0, 176, 240)
        Case "R/C"
            WS.Tab.Color = RGB(192, 0, 0)
        Case "R"
            WS.Tab.Color = RGB(255, 0, 0)
        Case "A"
            WS.Tab.Color = RGB(255, 192, 0)
        Case "G"
            WS.Tab.Color = RGB(0, 176, 80)
        Case Else
            WS.Tab.ColorIndex = xlColorIndexNone
        End Select
    Next WS
End Sub

Debugging highlights Case "C" get an error:

Run-time error '13'. Type mismatch.

Can anyone point me in the right direction?

Answer 1

You could try:

Option Explicit

Sub Set_tab_color()

    Dim WS As Worksheet

    For Each WS In ActiveWorkbook.Worksheets

        With WS

            If Not .Name = "Cover" _
                And Not .Name = "Due Dill" _
                And Not .Name = "Comm '19" _
                And Not .Name = "Comm '18" _
                And Not .Name = "Comm '17" _
                And Not .Name = "Clarizen_PLI" _
                And Not .Name = "Clarizen_milestones" _
                And Not .Name = "_blank" Then

                Select Case .Range("B5").Value

                Case "C"
                    .Tab.Color = RGB(0, 176, 240)
                Case "R/C"
                    .Tab.Color = RGB(192, 0, 0)
                Case "R"
                    .Tab.Color = RGB(255, 0, 0)
                Case "A"
                    .Tab.Color = RGB(255, 192, 0)
                Case "G"
                    .Tab.Color = RGB(0, 176, 80)
                Case Else
                    .Tab.ColorIndex = xlColorIndexNone
                End Select

            End If

        End With

    Next WS

End Sub