根据多个单元格值隐藏或取消隐藏工作表

Question

For work I'm trying to figure out how I can make a macro in excel to unhide sheets when you type a specific word in a column.
I'm totally new to this so it's a big search.

So far I got this:

Private Sub Worksheet_Change(ByVal Target As Range)
    If [C2] = "POMP" Then
        Sheets("POMP").Visible = True
    Else
        Sheets("POMP").Visible = False
    End If

    If [C2] = "TANK" Then
        Sheets("TANK").Visible = True
    Else
        Sheets("TANK").Visible = False
    End If

    If [C2] = "VENTILATOR" Then
        Sheets("VENTILATOR").Visible = True
    Else
        Sheets("VENTILATOR").Visible = False
    End If

    If [C2] = "MOTOR" Then
        Sheets("MOTOR").Visible = True
    Else
        Sheets("MOTOR").Visible = False
    End If
End Sub

It's just an example for a much bigger project. It works so far. When I type MOTOR in C2 then the tab of MOTOR unhides. Also for the others. But..

It actually has to work for the whole colomn C not only C2.

Could somebody help me with this?

Also another question. If there have to unhide 2 sheets when you type in a word, how can I put that in the code. Example: I type MOTOR and then the sheets MOTOR and POMP should unhide.

If you could help me with this to it would be such a help!

Answer 1

Just make a list of your sheet names as array. Loop through that array and check with the WorksheetFunction.Match method if the sheet name exists in column C to hide or show the sheet.

Note that Application.Match returns an error if the sheet name was not found in column C, so we use this to trigger the hide/show.

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim SheetNames() As Variant
    SheetNames = Array("POMP", "TANK", "VENTILATOR", "MOTOR") 'list your sheet names here

    Dim SheetName As Variant
    For Each SheetName In SheetNames
        Dim MatchedRow As Variant
        MatchedRow = Application.Match(SheetName, Me.Columns("C"), 0)

        On Error Resume Next 'catch error if sheet name does not exist
        ThisWorkbook.Worksheets(SheetName).Visible = Not IsError(MatchedRow)
        If Err.Number <> 0 Then MsgBox "Worksheet '" & SheetName & "' not found!", vbCritical
        On Error GoTo 0
    Next SheetName
End Sub