需要对 xslt 1.0 执行双重嵌套排序

Question

Worked on the solution Sandy gave me, it worked fine, but then I realized the code is more nested. Been trying to solve it but no luck.

This part is working fine on sorting the WorkingQueue.

<xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="WorkingQueues">
        <xsl:copy>
            <xsl:for-each select="WorkingQueue">
                <xsl:sort select="@queueId" order="ascending" data-type="number"/>
                <xsl:copy>
                    <xsl:copy-of select="@*|node()"/>
                </xsl:copy>
            </xsl:for-each>
        </xsl:copy>
    </xsl:template>

Adding this part (+ removing the WorkingQueue) made it sort for the ValidationAction Somehow I need to shift this part into the first for-each loop. All my efforts returned a mess.

<xsl:template match="Actions">
        <xsl:copy>
            <xsl:for-each select="ValidationAction">
                <xsl:sort select="@actionLabel" order="ascending"/>
                <xsl:copy>
                    <xsl:copy-of select="@*|node()"/>
                </xsl:copy>
            </xsl:for-each>
        </xsl:copy>
    </xsl:template>

This is the code which needs to be sorted on WorkingQueue@queueId and ValidationAction@actionLabel

<Export>
    <WorkingTemplates>
        <WorkingTemplate label="MM_DR">
            <WorkingQueues>
                <WorkingQueue queueId="132" right="READ_WRITE">
                    <Actions>
                        <ValidationAction actionLabel="BrkNotOk" enabled="true"/>
                        <ValidationAction actionLabel="AddComment" enabled="true"/>
                    </Actions>
                </WorkingQueue>
                <WorkingQueue queueId="49" right="READ_WRITE">
                    <Actions>
                        <ValidationAction actionLabel="BrkNotOk" enabled="true"/>
                        <ValidationAction actionLabel="AddComment" enabled="true"/>
                    </Actions>
                </WorkingQueue>
            </WorkingQueues>
        </WorkingTemplate>
        <WorkingTemplate label="FX_MA">
            <WorkingQueues>
                <WorkingQueue queueId="123" right="READ_WRITE">
                    <Actions>
                        <ValidationAction actionLabel="BrkNotOk" enabled="true"/>
                        <ValidationAction actionLabel="AddComment" enabled="true"/>
                    </Actions>
                </WorkingQueue>
                <WorkingQueue queueId="60" right="READ_WRITE">
                    <Actions>
                        <ValidationAction actionLabel="Accept" enabled="true"/>
                    </Actions>
                </WorkingQueue>
            </WorkingQueues>
        </WorkingTemplate>
    </WorkingTemplates>
</Export>

Expected result:

<Export>
    <WorkingTemplates>
        <WorkingTemplate label="MM_DR">
            <WorkingQueues>
                <WorkingQueue queueId="49" right="READ_WRITE">
                    <Actions>
                        <ValidationAction actionLabel="AddComment" enabled="true"/>
                        <ValidationAction actionLabel="BrkNotOk" enabled="true"/>
                    </Actions>
                </WorkingQueue>
                <WorkingQueue queueId="132" right="READ_WRITE">
                    <Actions>
                        <ValidationAction actionLabel="AddComment" enabled="true"/>
                        <ValidationAction actionLabel="BrkNotOk" enabled="true"/>
                    </Actions>
                </WorkingQueue>
            </WorkingQueues>
        </WorkingTemplate>
        <WorkingTemplate label="FX_MA">
            <WorkingQueues>
                <WorkingQueue queueId="60" right="READ_WRITE">
                    <Actions>
                        <ValidationAction actionLabel="Accept" enabled="true"/>
                    </Actions>
                </WorkingQueue>
                <WorkingQueue queueId="123" right="READ_WRITE">
                    <Actions>
                        <ValidationAction actionLabel="AddComment" enabled="true"/>
                        <ValidationAction actionLabel="BrkNotOk" enabled="true"/>
                    </Actions>
                </WorkingQueue>
            </WorkingQueues>
        </WorkingTemplate>
    </WorkingTemplates>
</Export>

Answer 1

I am guessing (:) you want to do:

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="WorkingQueues">
    <xsl:copy>
        <xsl:apply-templates select="WorkingQueue">
            <xsl:sort select="@queueId" data-type="number" order="ascending"/>
        </xsl:apply-templates>
    </xsl:copy>
</xsl:template>

<xsl:template match="Actions">
    <xsl:copy>
        <xsl:apply-templates select="ValidationAction">
            <xsl:sort select="@actionLabel" data-type="text" order="ascending"/>
        </xsl:apply-templates>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>