如何替换列中单元格中的文本？

Question

I'm building a tool to parse/format copy pasted data into a more organized table.

The final table is 4 columns and the 3rd column is email addresses.

I would like to replace (@gmail.com) in the email address column with a value that says "external email address". The size of the table changes when new data in input.

With my limited knowledge I've not been successful.

Answer 1

Dim lastRow as long, ws as Worksheet, i as long

Set ws = ThisWorkBook.Worksheets("YourWorksheetName")

' Suppose your third column is column C
lastRow = ws.Cells(ws.Rows.Count, "C").End(xlUp).Row
' Suppose the first row is the header, column C = 3 in terms of index
For i = 2 To lastRow
    If ws.Cells(i,3).Value Like "*@gmail.com*" Then
         ws.Cells(i,3).Value = "external email address"
    End If
Next i

Answer 2

It'd be nice if You showed what You mean by "A lot of the stuff is already done" and what You've achieved so far but...

You could try using InStr() like this,

Sub ReplaceExternalEmails()

    'ofc sheet's and listObj's indexes or "names" matters and depends on your case, try to figure these out
    Dim someTable As ListObject
    Set someTable = Sheets(1).ListObjects(1)

    'Loop through 3rd column to check for external mails
    Dim cel As Range
    For Each cel In someTable.DataBodyRange.Columns(3).Cells
        If InStr(cel.Value, "@gmail.com") Then
            cel.Value = "external email address"
        End If
    Next cel

End Sub

You could also add

cel.ClearFormats

inside for loop, or some other formating so it won't stay underlined blue if You care somehow.

Another way to approach this (which is probably faster with larger datasets) is by replacing values, which is equivalent to CTRL+F / Replace method like this,

Sub ReplaceExternalEmails()

    Dim someTable As ListObject
    Set someTable = Sheets(1).ListObjects(1)

    Dim fnd As Variant: fnd = "*@gmail.com"
    Dim rpl As Variant: rpl = "external email address"

    someTable.DataBodyRange.Columns(3).Replace _
        What:=fnd, Replacement:=rpl

End Sub