如何在verilog systemverilog中分配给genvar？

Question

I need to wire quite a few registers into a register file. The registers control a multi-channel receiver so they are repeated for all the Nchan receiver channels. Here is the section of code. The error message says: "syntax error near '='". This happens on the line "regoffset = 0+Nsys_reg+Nchan*0;"and all the other such assignments.

I am trying to use the regoffset genvar to improve readability, etc. How do I modify the value of a genvar inside a generate statement? Is there a better approach?

// receiver registers
genvar chanvar, regoffset;

// individual channel resets in a single register
generate
    regoffset = 0+Nsys_reg+Nchan*0;
    for (chanvar=0; chanvar<Nchan; chanvar++) begin
        assign chan_reset[chanvar] = slv_reg[regoffset][chanvar];
    end 
    assign slv_read[regoffset] = slv_reg[regoffset];

    // the start up delay registers, wired sequentially.
    regoffset = 1+Nsys_reg+Nchan*0;
    for (chanvar=0; chanvar<Nchan; chanvar++) begin
        assign start_delay[chanvar] = slv_reg[regoffset+chanvar][11:0];
        assign slv_read[regoffset+chanvar] = slv_reg[regoffset+chanvar];
    end 

    // the starting doppler registers, wired sequentially.
    regoffset = 1+Nsys_reg+Nchan*1;
    for (chanvar=0; chanvar<Nchan; chanvar++) begin
        assign start_dopp[chanvar] = slv_reg[regoffset+chanvar];
        assign slv_read[regoffset+chanvar] = slv_reg[regoffset+chanvar];
    end 

    // the SV select registers, wired sequentially.
    regoffset = 1+Nsys_reg+Nchan*2;
    for (chanvar=0; chanvar<Nchan; chanvar++) begin
        assign ca_sel[chanvar] = slv_reg[regoffset+chanvar][5:0];
        assign slv_read[regoffset+chanvar] = slv_reg[regoffset+chanvar];
    end 
endgenerate

Answer 1

Use a localparam instead of a genvar .

// receiver registers
genvar chanvar;

// individual channel resets in a single register
generate
    localparam regoffset0 = 0+Nsys_reg+Nchan*0;
    for (chanvar=0; chanvar<Nchan; chanvar++) begin
        assign chan_reset[chanvar] = slv_reg[regoffset0][chanvar];
    end 
    assign slv_read[regoffset0] = slv_reg[regoffset0];

    // the start up delay registers, wired sequentially.
    localparam regoffset1 = 1+Nsys_reg+Nchan*0;
    for (chanvar=0; chanvar<Nchan; chanvar++) begin
       assign start_delay[chanvar] = slv_reg[regoffset1+chanvar][11:0];
       assign slv_read[regoffset1+chanvar] = slv_reg[regoffset1+chanvar];
    end 
...
endgenerate

You could also use a function

function integer regoffset(integer N);
  regoffset = 1+N*Nsys_reg+Nchan*N;
endfunction
    genvar chanvar;

    // individual channel resets in a single register
     assign slv_read[regoffset(0)-1] = slv_reg[regoffset(0)-1];
    generate
        for (chanvar=0; chanvar<Nchan; chanvar++) begin
             assign chan_reset[chanvar] = slv_reg[regoffset(0)-1][chanvar];

             // the start up delay registers, wired sequentially.
             assign start_delay[chanvar] = slv_reg[regoffset(0)+chanvar][11:0];
             assign slv_read[regoffset(0)+chanvar] = slv_reg[regoffset(0)+chanvar];

             // the starting doppler registers, wired sequentially.
             assign start_dopp[chanvar] = slv_reg[regoffset(1)+chanvar];
             assign slv_read[regoffset(1)+chanvar] = slv_reg[regoffset(1)+chanvar];

             // the SV select registers, wired sequentially.
             assign ca_sel[chanvar] = slv_reg[regoffset(2)+chanvar][5:0];
             assign slv_read[regoffset(2)+chanvar] = slv_reg[regoffset(2)+chanvar];
        end       



    endgenerate