如何参考 OLE 工作簿？

Question

In one of my worksheets I have another workbook inserted as an embedded object, which I need to open to read some of its fields.

I open this file using OLEobj.Verb xlVerbOpen , and assign it to a Workbook variable called wbR . Because its name may change each time it is opened, the only way I have figured to do so is using ActiveWorkbook .

This works when I run the code line by line. However when the whole macro is run from a button, most of the time ActiveWorkbook will be considered the same as ThisWorkBook . I tried using Wait and Sleep.

The part giving this problem:

For Each OLEobj In ThisWorkbook.Sheets("SheetName").OLEObjects
    Set OLEobj = wsr.OLEObjects(OLEobj.Name)
    OLEobj.Verb xlVerbOpen
    Application.Wait (Now + TimeValue("0:00:05"))
    'Sleep 5000
    Set wbR = ActiveWorkbook
    Exit For
Next OLEobj

Answer 1

Using .Verb xlVerbOpen can be dicey to get the "active" application.

Activate (start/open) the object and use the OLEFormat.Object.Object to get the workbook object.

Is this what you are trying?

Option Explicit

Sub Sample()
    Dim ws As Worksheet
    Dim shp As Shape
    Dim wb As Object

    '~~> Change this to the relevant sheet where the excel file is embedded
    Set ws = Sheet1

    '~~> Change this to the relevant object name
    Set shp = ws.Shapes("Object 1") ' OLEobj.Name? from your code?

    '~~> Activate it (Open it)
    shp.OLEFormat.Activate

    '~~> Get the workbook object
    Set wb = shp.OLEFormat.Object.Object

    With wb
        '
        '~~> Work with the workbook object here
        '

        MsgBox .Worksheets.Count
    End With
End Sub

Answer 2

Following your suggestion I have changed my code as seen below and it does work as a charm. Thank you so much for your help!!

For Each OLEobj In ThisWorkbook.Sheets("Ratios").OLEObjects
    Set OLEobj = wsr.OLEObjects(OLEobj.Name)
    'OLEobj.Verb xlVerbOpen
    OLEobj.Activate
    **Set wbR = OLEobj.Object**  ' New line that solves the issue.
    Exit For
Next OLEobj