在T-SQL中计算日期差异

Question

Guys, I am trying to write a stored procedure in T-SQL (SQL Server) that will select records based on a date field, keeping a variance of minutes in mind. Something like this:

CREATE PROCEDURE spGetCustomers(@DateRange DATETIME, @Variance int) AS
-- The next line is where I need help
-- I'm trying to subtract X amount of minutes from the date
-- So if @Variance = 4 AND @DateRange = '6/10/2009 1:15pm'
-- Then @StartDate should equal '6/10/2009 1:11pm'
DECLARE @StartDate = @DateRange - @Variance
-- I also need an @EndDate, which will be X amount of minutes
-- in the future. So if @Variance = 4 AND @DateRange = '6/10/2009 1:15pm'
-- Then @EndDate should equal '6/10/2009 1:19pm'
DECLARE @EndDate = @DateRange + @Variance

SELECT * FROM Customers WHERE Created BETWEEN @StartDate AND @EndDate

Hopefully this makes sense and someone can help me out! Thanks in advance

Answer 1

Check this out:

http://msdn.microsoft.com/en-us/library/ms186819(SQL.90).aspx

The DATEADD function allows you to add virtually any part of a date to another date object, it should be everything you need.

So basically do:

SELECT DATEADD(second, @Variance, @DateRange)

Answer 2

The following script provides an example that should get you started.

create table tmp_Customers
(
    ID int identity(1,1),
    CreatedDate datetime default getDate() not null,
    Description varchar(15)
);
go

insert into tmp_Customers(Description) values('SomeData');
insert into tmp_Customers(Description) values('SomeData2');
insert into tmp_Customers(Description) values('SomeData3');
go

create procedure usp_GetCustomers

    @iVarianceMinutes   int,
    @iDateRange         datetime

as

    set nocount on

    declare @startDate  datetime
    declare @endDate    datetime

    --Define the date ranges for the select query
    set @startDate = dateAdd(minute,-@iVarianceMinutes,@iDateRange)
    set @endDate = dateAdd(minute,@iVarianceMinutes,@iDateRange)

    --Get the Customers that were created within this time range.
    SELECT * 
    FROM tmp_Customers 
    WHERE CreatedDate >= @startDate and CreatedDate < @endDate 


return(0);
go


--Execute the procedure
declare @testDate datetime;
set @testDate = getDate();

exec usp_GetCustomers 5,@testDate 

--drop procedure usp_GetCustomers
--drop table tmp_Customers