如何通过 SAS 中另一个表中的内容过滤表？

Question

I appreciate the help with this:

I have a table A with 2 columns ID and var1.

ID  | var1
____________
1   |  4
2   |  5
3   |  2
4   |  3

I have another table B with other columns but only some of the rows:

ID  | var2
____________
2   |  "Apple"
4   |  "Orange"

What I want is to be able to create a table of all rows in A for which the ID is NOT in table B

ID  | var1
____________
1   |  4
3   |  2

I could do a left join of A to B, filter using 'where var2 is null' and then drop that column, but that seems like an overly complicated way to deal with this.

Answer 1

Slight modification on one of Richard's solution above, SQL using not in instead.

proc sql;
  create table want_way2 as
  select * from have
  where ID not in (select ID from filter)
; 
quit;

Answer 2

You can merge with IN= automatic flags, or SQL query with an existential predicate

Example:

data have;
input ID  var1; datalines;
1     4
2     5
3     2
4     3
;
data filter;
input ID  var2 $; datalines;
2     Apple
4     Orange
;

data want_way1;
  merge have filter (in=filter keep=ID);
  by ID;
  if not filter;
run;

proc sql;
  create table want_way2 as
  select * from have
  where not exists (select * from filter where filter.ID=have.ID)
; 

A third way could be a JOIN to an exception sub-select

proc sql; 
  create table want_way3 as
  select have.* from have
  join
  (select ID from have except select ID from filter) as keeper
  on have.ID = keeper.ID
  ;