XSLT 变换未应用于复杂 XML

Question

I have a custom XML as shwon below

<AllValues xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
    <content>
        <data>
            <item>
                <value xsi:type="DATETIME">
                    <value>2020-12-31T09:30:00+00:00</value>
                </value>
            </item>
        </data>
    </content>
</AllValues>

From the defined styles sheet I would like to extract out the 2020-12-31T09:30:00+00:00 as September 24th, 2020 09:30 . However seems like the style sheet fails to identify the element in this case.

My style sheet (adapted from here ) is defined as below

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>
    <xsl:template match="/">
        <output>
            <xsl:variable name="month" select="substring(date, 6, 2)"/>
            <xsl:choose>
                <xsl:when test="$month=1">January</xsl:when>
                <xsl:when test="$month=2">February</xsl:when>
                <xsl:when test="$month=3">March</xsl:when>
                <xsl:when test="$month=4">April</xsl:when>
                <xsl:when test="$month=5">May</xsl:when>
                <xsl:when test="$month=6">June</xsl:when>
                <xsl:when test="$month=7">July</xsl:when>
                <xsl:when test="$month=8">August</xsl:when>
                <xsl:when test="$month=9">September</xsl:when>
                <xsl:when test="$month=10">October</xsl:when>
                <xsl:when test="$month=11">November</xsl:when>
                <xsl:when test="$month=12">December</xsl:when>
            </xsl:choose>
            <xsl:text> </xsl:text>
            <xsl:variable name="day" select="number(substring(date, 9, 2))"/>
            <xsl:value-of select="$day"/>
            <xsl:choose>
                <xsl:when test="$day=1 or $day=21 or $day=31">st</xsl:when>
                <xsl:when test="$day=2 or $day=22">nd</xsl:when>
                <xsl:otherwise>th</xsl:otherwise>
            </xsl:choose>
            <xsl:text>, </xsl:text>
            <xsl:value-of select="substring(date, 1, 4)"/>
            <xsl:text> </xsl:text>
            <xsl:value-of select="substring(date, 12, 5)"/>
        </output>
    </xsl:template>
</xsl:stylesheet>

A very basic scenario of this seems to work fine but I cant get a complect xml transformed here. Here is the implementation of a basic situation where it works https://xsltfiddle.liberty-development.net/bEzknt7/1

Would really appreciate some help here

Answer 1

You are simply not matching the right node in your XSLT.
Change the date node in your expressions to . and set the right context node in your template:

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="//*[@xsi:type='DATETIME']/value">
        <xsl:element name="output">
            <xsl:variable name="month" select="substring(., 6, 2)"/>
            <xsl:choose>
                <xsl:when test="$month=1">January</xsl:when>
                <xsl:when test="$month=2">February</xsl:when>
                <xsl:when test="$month=3">March</xsl:when>
                <xsl:when test="$month=4">April</xsl:when>
                <xsl:when test="$month=5">May</xsl:when>
                <xsl:when test="$month=6">June</xsl:when>
                <xsl:when test="$month=7">July</xsl:when>
                <xsl:when test="$month=8">August</xsl:when>
                <xsl:when test="$month=9">September</xsl:when>
                <xsl:when test="$month=10">October</xsl:when>
                <xsl:when test="$month=11">November</xsl:when>
                <xsl:when test="$month=12">December</xsl:when>
            </xsl:choose>
            <xsl:text> </xsl:text>
            <xsl:variable name="day" select="number(substring(., 9, 2))"/>
            <xsl:value-of select="$day"/>
            <xsl:choose>
                <xsl:when test="$day=1 or $day=21 or $day=31">st</xsl:when>
                <xsl:when test="$day=2 or $day=22">nd</xsl:when>
                <xsl:otherwise>th</xsl:otherwise>
            </xsl:choose>
            <xsl:text>, </xsl:text>
            <xsl:value-of select="substring(., 1, 4)"/>
            <xsl:text> </xsl:text>
            <xsl:value-of select="substring(., 12, 5)"/>
        </xsl:element>
    </xsl:template>
</xsl:stylesheet>

Its output is:

<output>December 31st, 2020 09:30</output>

This works fine for your MCVE and works for all elements with the xsi:type attribute equal to DATETIME .

Answer 2

If your input has multiple dateTime values that need to be converted, then define a named template to serve as a function that can be called when a dateTime value is encountered. For example:

XML

<AllValues xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
    <content>
        <data>
           <item>
                <value xsi:type="STRING">
                    <value>Alpha</value>
                </value>
            </item>
            <item>
                <value xsi:type="DATETIME">
                    <value>2019-08-02T15:05:00+00:00</value>
                </value>
            </item>
        </data>
        <data>
           <item>
                <value xsi:type="STRING">
                    <value>Bravo</value>
                </value>
            </item>
            <item>
                <value xsi:type="DATETIME">
                    <value>2020-12-31T09:30:00+00:00</value>
                </value>
            </item>
        </data>
    </content>
</AllValues>

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="value[@xsi:type='DATETIME']/value">
    <xsl:copy>
        <xsl:call-template name="convert-dateTime">
            <xsl:with-param name="dateTime" select="."/>
        </xsl:call-template>
    </xsl:copy>
</xsl:template>

<xsl:template name="convert-dateTime">
    <xsl:param name="dateTime"/>
    <xsl:variable name="month" select="substring($dateTime, 6, 2)"/>
    <xsl:choose>
        <xsl:when test="$month=1">January</xsl:when>
        <xsl:when test="$month=2">February</xsl:when>
        <xsl:when test="$month=3">March</xsl:when>
        <xsl:when test="$month=4">April</xsl:when>
        <xsl:when test="$month=5">May</xsl:when>
        <xsl:when test="$month=6">June</xsl:when>
        <xsl:when test="$month=7">July</xsl:when>
        <xsl:when test="$month=8">August</xsl:when>
        <xsl:when test="$month=9">September</xsl:when>
        <xsl:when test="$month=10">October</xsl:when>
        <xsl:when test="$month=11">November</xsl:when>
        <xsl:when test="$month=12">December</xsl:when>
    </xsl:choose>
    <xsl:text> </xsl:text>
    <xsl:variable name="day" select="number(substring($dateTime, 9, 2))"/>
    <xsl:value-of select="$day"/>
    <xsl:choose>
        <xsl:when test="$day=1 or $day=21 or $day=31">st</xsl:when>
        <xsl:when test="$day=2 or $day=22">nd</xsl:when>
        <xsl:otherwise>th</xsl:otherwise>
    </xsl:choose>
    <xsl:text>, </xsl:text>
    <xsl:value-of select="substring($dateTime, 1, 4)"/>
    <xsl:text> </xsl:text>
    <xsl:value-of select="substring($dateTime, 12, 5)"/>
</xsl:template>

</xsl:stylesheet>

Result

<?xml version="1.0" encoding="UTF-8"?>
<AllValues xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
  <content>
    <data>
      <item>
        <value xsi:type="STRING">
          <value>Alpha</value>
        </value>
      </item>
      <item>
        <value xsi:type="DATETIME">
          <value>August 2nd, 2019 15:05</value>
        </value>
      </item>
    </data>
    <data>
      <item>
        <value xsi:type="STRING">
          <value>Bravo</value>
        </value>
      </item>
      <item>
        <value xsi:type="DATETIME">
          <value>December 31st, 2020 09:30</value>
        </value>
      </item>
    </data>
  </content>
</AllValues>