将 Excel 范围复制到 Word 文档，包括其隐藏的子范围

Question

I am trying to copy an Excel Range, using the.Copy method, which has hidden and not hidden parts. But, after copy the range, when I paste it in a word.docx document, only the not hidden parts are pasted.

Is it possible paste the whole range, including the hidden parts?

Even if I make hidden = false, then copy, then hidden = true, it doesn't work. It still pastes only not hidden parts.

The code I have now is as follows. Macro2 and Macro3 do not work, only Macro4 works for me, but Rows(1) have to be not hidden, which I don't want.

Sub Macro1()
    Rows(1).Hidden = True
    Rows(2).Hidden = False
End Sub

Sub Macro2()
    Range(Cells(1, 1), Cells(2, 1)).Copy
End Sub

Sub Macro3()
    Rows(1).Hidden = False
    Range(Cells(1, 1), Cells(2, 1)).Copy
    Rows(1).Hidden = True
End Sub

Sub Macro4()
    Rows(1).Hidden = False
    Range(Cells(1, 1), Cells(2, 1)).Copy
End Sub

Answer 1

An InlineShape / OLEFormat approach

The code below functions from Excel (with the use of the Microsoft Word ##.0 Object Library reference) by hooking into a word document, and embedding an Excel document as an InlineShape . This object is then editted directly, allowing for the data to be copied over.

There may still be a simpler option out there, but this was the best that I could come up with.

Public Function CopyToWord(ByRef rng As Excel.Range, ByRef wd As Word.Document) _
                    As Word.InlineShape
    
    Dim wd_wb   As Excel.Workbook   '' word workbook
    Dim wd_ws   As Excel.Worksheet  '' word wordsheet
    Dim ole_xl  As Word.OLEFormat   '' the format object that holds the above
    Dim wd_is   As Word.InlineShape '' the shape object that holds the above
  
    '' add inline shape
    Set wd_is = wd.Content.InlineShapes.AddOLEObject( _
                ClassType:="Excel.Sheet.12", _
                Filename:="", _
                LinkToFile:=False, _
                DisplayAsIcon:=False)
    Set ole_xl = wd_is.OLEFormat    '' get format
    Call ole_xl.Activate            '' start editing
    Set wd_wb = ole_xl.Object       '' get workbook
    Set wd_ws = wd_wb.Sheets(1)     '' get worksheet
    
    '' actually do the copying
    Call rng.Copy(Destination:=wd_ws.[A1].Resize(rng.Rows.Count, rng.Columns.Count))

    Call wd_wb.Close                '' stop editting
    Set CopyToWord = wd_is          '' return inline shape object

End Function

Here is a demo subroutine that shall show that the function

Public Sub demo()
  
    [A1] = "Sneaky"
    [A:A].EntireRow.Hidden = True
  
    Dim word_doc As New Word.Document
    Let word_doc.Application.Visible = True

    Call CopyToWord(rng:=[A1:B2], wd:=word_doc) '' or `CopyToWord [A1:B2], word_doc`

End Sub

A useful reference