将 Excel 图表复制/粘贴到 PowerPoint 错误

Question

I am trying to take 60 charts in an Excel workbook and paste them to PowerPoint. It has been working fine up until we converted to Office 365. Now I am getting an error

The specified data type is unavailable

Here is the code:

copy_chart "318Pivot", "cht404_318", 3

Public Function copy_chart(sheet, chart, slide)
Dim oshp As Shape
Dim PPApp As Object
Dim PPPres As Object
Dim PPSlide As Object
Dim PPShape As Object

Set PPApp = GetObject(, "Powerpoint.Application")
Set PPPres = PPApp.ActivePresentation
PPApp.ActiveWindow.ViewType = ppViewSlide
PPApp.ActiveWindow.View.GotoSlide (slide)

Worksheets(sheet).Activate
ActiveSheet.ChartObjects(chart).chart.CopyPicture Appearance:=xlScreen, Size:=xlScreen, Format:=xlPicture

Set PPSlide = PPPres.Slides(PPApp.ActiveWindow.Selection.SlideRange.SlideIndex)

' paste and select the chart picture
PPSlide.Shapes.PasteSpecial DataType:=ppPasteJPG  '**This is where it errors out**

'With PPShape
For j = 1 To PPSlide.Shapes.Count
With PPSlide.Shapes(j)
    If .Type = msoPicture Then
        .LockAspectRatio = False
        .Height = 5# * 72
        .Width = 10# * 72
        .Left = 0# * 72
        .Top = 1.5 * 72
    End If
End With
Next j
DoEvents

' Clean up
Set PPSlide = Nothing
Set PPPres = Nothing
Set PPApp = Nothing
Set PPShape = Nothing

End Function

It worked great before. I have tried ppPasteDefault and ppPasteEnhancedMetafile but they both made the PowerPoint file >30 MB. Before when it worked, it was 3 MB.

Does anyone know why I can't use ppPasteJPG anymore all of the sudden and how to correct the code?

Answer 1

If ytou are not using early binding, Excel VBA won't know what ppPasteJPG means. But ppPasteJPG is merely a named constant with a value of 5. So replace

PPSlide.Shapes.PasteSpecial DataType:=ppPasteJPG

with

PPSlide.Shapes.PasteSpecial DataType:=5

Answer 2

Got it to work. Found that the copy line was not actually copying the Chart for some reason. Not sure why copy ChartArea works and copy Chart does not though.

'ActiveSheet.ChartObjects(chart).chart.CopyPicture Appearance:=xlScreen, Size:=xlScreen, Format:=xlPicture
Worksheets(sheet).Activate
ActiveSheet.ChartObjects(chart).Activate
ActiveChart.ChartArea.Copy
' test to see if the clipboard is empty

Set PPSlide = PPPres.Slides(PPApp.ActiveWindow.Selection.SlideRange.SlideIndex)

' paste and select the chart picture
PPSlide.Shapes.PasteSpecial DataType:=ppPasteJPG