从另一个表单 vba Excel 更新组合框

Question

I have a Userform1 form, inside which there is a combobox called categories, and this field is a list of options that I load into the combobox from a table in excel (using rowsource in the object properties).

From the opened Userform1, if I want to add a new option to the list that appears in the categories field, I put a button that opens a Userform2 where I can create categories. But once I create it and close Userform2 the combobox of Userform1 is not updated. How can I refresh it so that the new option I created from Userform 2 appears?

Thank you very much

Answer 1

Set the rowsource at runtime in UserForm_Initialize()

Code in Userform1

Option Explicit

Private Sub UserForm_Initialize()
    PopulateCombo
End Sub

Sub PopulateCombo()
    Dim ws As Worksheet
    Dim rng As Range
    Dim lRow As Long
    
    '~~> Change this to the relevant sheet
    Set ws = Sheet1
    
    With ws
        '~~> Find Last Row in Col A
        '~~> Change column as applicable
        lRow = .Range("A" & .Rows.Count).End(xlUp).Row
        
        '~~> Identify the range starting from A1
        '~~> Change as applicable
        Set rng = .Range("A1:A" & lRow)
        
        '~~> Set your rowsource
        ComboBox1.RowSource = rng.Address(, , , True)
    End With
End Sub

And then you can reset the RowSource using the PopulateCombo code from Userform2

Something like

Code in Userform2

Private Sub CommandButton1_Click()
    '
    '~~> After adding data
    '
    
    UserForm1.PopulateCombo
End Sub