Delphi 在字符串中查找下划线

Question

I have two strings named "ver1" and "ver2" the input in the strings looks like this:

Ver1: B2CD1 Ver2: B3A10

Sometimes it looks like this:

Ver1: B2CD1_A1 Ver2: B3A10_DE

My question: How can I search in both strings after the "_" in it and return a value from it?

By the way the function is for software version comparison. Please just give me advice in my question not my entire function.

Thanks

uses
  Classes, SysUtils, StrUtils, Forms, Controls, Graphics, Dialogs, StdCtrls;


type

  { TForm1 }

  TForm1 = class(TForm)
    Button1: TButton;
    Edit1: TEdit;
    Edit2: TEdit;
    Memo1: TMemo;
    procedure Button1Click(Sender: TObject);
    procedure Edit1Change(Sender: TObject);
    procedure Memo1Change(Sender: TObject);
  private

  public

  end;

var
  Form1: TForm1;

implementation

{$R *.lfm}

function isSoftwareGreater(ver1,ver2 : string) : byte;
var i : integer;
    tmp1,tmp2 : string;
    cver1,cver2 : int64;

begin
{
  Return values:
      0: versions are equal
      1: ver1 is bigger then ver2
      2: ver2 is bigger then ver1
    253: ver1 is too big (could not be converted to int64)
    254: ver2 is too big (could not be converted to int64)
}

  tmp1 := '';
  tmp2 := '';

  for i := 1 to length(ver1) do
   begin
    if (ver1[i] in ['a'..'z']) or (ver1[i] in ['A'..'Z']) then
     tmp1 := tmp1 + inttostr(Ord(ver1[i]));
    if (ver1[i] in ['0'..'9']) then
     tmp1 := tmp1 + ver1[i];
   end;
  for i := 1 to length(ver2) do
   begin
    if (ver2[i] in ['a'..'z']) or (ver2[i] in ['A'..'Z']) then
     tmp2 := tmp2 + inttostr(Ord(ver2[i]));
    if (ver2[i] in ['0'..'9']) then
     tmp2 := tmp2 + ver2[i];
   end;

  if not TryStrToInt64(tmp2,cver2) then
   begin
    isSoftwareGreater := 254;
    exit;
   end;
  if not TryStrToInt64(tmp1,cver1) then
   begin
    isSoftwareGreater := 253;
    exit;
   end;

  if ver1 > ver2 then
    isSoftwareGreater := 1
  else if ver2 > ver1 then
    isSoftwareGreater := 2
  else if ver1 = ver2 then
    isSoftwareGreater := 0;

end;
 

Answer 1

You can search a string using the Pos() function . It returns the index of the found character or 0 if not found.

var
    Index     : Integer;
    SubString : String;
begin
    Index := Pos('_', Ver1);
    if Index > 0 then
        SubString := Copy(Ver1, Index + 1, MAXINT)
    else
        SubString := '';
end;

If you want to extract text between two markers, you have to search for the first as shown above and then search for the second, starting right after the first one. Pos() has an optional 3rd argument to specify where to start search. This gives:

var
    Index1    : Integer;
    Index2    : Integer;
    SubString : String;
begin
    Index1 := Pos('_', Ver1);
    if Index1 > 0 then begin
        Index2 := Pos('_', Ver1, Index1 + 1);
        if Index2 > 0 then
            // We have two underscore, extract text between them
            SubString := Copy(Ver1, Index1 + 1, Index2 - Index1 - 1)
        else
            // Only one underscore, extract text from the first to the end of string
            SubString := Copy(Ver1, Index1 + 1, MAXINT);
    end
    else
        SubString := '';
end;

Answer 2

You can use ContainsStr() to check if the strings has '_' and then use SubString() and IndexOf()

function GetString(const AString, ASubString: string): string;
begin
  Result:= EmptyStr;
  if ContainsStr(AString, ASubString) then
    Result:= AString.Substring(Astring.IndexOf(ASubString)+1, AString.Length);
end;