如何引用多个按钮？ (VB.NET)

Question

So, im building this project this version of Tic Tac Toe where each of the spaces of the main game have another Tic Tac Toe game inside. Search for "Ultimate Tic Tac Toe" if you want to know more. Within each space of the Grid, I have one button. 9 per game, per 9 games equals 81 buttons.

My question is: is there a way in VB.NET where I can link multiple buttons together? I want to create a variable that increases by one each time any of these buttons is pressed. Do I have to do this in each individual sub, or is there a way to do this to multiple buttons? (I want to have other buttons: one to restart, one to exit, but these should not be included in this sum, only the 81 buttons I mentioned.)

Answer 1

There is more than one way to accomplish this. Both the methods I will show you involve writing a custom event handler. The method must match the signature of the normal handler. The example here is for a Button.Click event.

Private Sub MyButtonHandler(sender As Object, e As EventArgs)
    Dim b = DirectCast(sender, Button)
    Dim t = b.Tag.ToString
    If t = "SomeValue" Then
        'Do something
    End If
End Sub

In the Form Designer select the button you need and open the Properties window.

Select the lighting bolt (left of the wrench).

Look for the Click event. Click the drop down arrow.

Low and behold, there is you method listed as a choice to handle this event. This is because the method has the appropriate parameters, namely sender As Object and e As EventArgs. Just select your method for each button you want to use that method.

When you check back to the code, you will see that a Handles clause has been automatically added to your method. You can have multiple Handles clauses.

Private Sub MyButtonHandler(sender As Object, e As EventArgs) Handles Button1.Click

Another way to do this is with AddHandler.

Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
    AddHandler Button1.Click, AddressOf MyButtonHandler
End Sub

Answer 2

If you already added all the Buttons to your Interface, AND you used a consistent NAMING CONVENTION, then you can use a couple of loops to find each button and wire them up using AddHandler as Mary has already suggested.

In this example, the buttons are name "btnC0R0" through "btnC2R2", where the number after the "C" represents the column and the number after the "R" represents the row.

We can search for these buttons in the Load() event of the Form. I've also placed a Point structure in the .Tag property of each button so you can use that information when the button is clicked:

Public Class Form1

    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        Dim btn As Button
        Dim ctlName As String
        For r As Integer = 0 To 2
            For c As Integer = 0 To 2
                ctlName = "btnC" & c & "R" & r
                btn = Me.Controls.Find(ctlName, True).FirstOrDefault
                If Not IsNothing(btn) Then
                    btn.Tag = New Point(c, r)
                    AddHandler btn.Click, AddressOf btn_Click
                End If
            Next
        Next
    End Sub

    Private Sub btn_Click(sender As Object, e As EventArgs)
        Dim btn As Button = DirectCast(sender, Button)
        Dim pt As Point = DirectCast(btn.Tag, Point)
        Me.Text = pt.X & ", " & pt.Y
    End Sub

End Class

Output:

Answer 3

  Private Sub btnInp1_Click(sender As Object, e As EventArgs) Handles btnInp1.Click, btnInp2.Click, btnInp3.Click, btnInp4.Click, btnInp5.Click, btnInp6.Click, btnInp7.Click, btnInp8.Click, btnInp9.Click


    If player = 1 Then
        player = 2
    Else
        player = 1
    End If

    Me.Text = "Player" & player

    If player = 1 Then
        sender.Text = "X"
    Else
        sender.Text = "O"
    End If
    sender.Enabled = False
End Sub