如果本月修改，如何查看文件夹中的所有文件？

Question

I need to implement a condition to my code wherein it checks if all files are modified the same month the code is run. How do I modify this code to check for month instead?

Sub LookForNew()
Dim n As String, msg As String, d As Date
msg = ""
Set fso = CreateObject("Scripting.FileSystemObject")
Set fils = fso.GetFolder("C:\TestFolder").Files
For Each fil In fils
    n = fil.Name
    d = fil.DateCreated
    If d >= Date - 1 Then
        msg = msg & n & vbTab & d & vbCrLf
    End If
Next fil
If msg = "" Then
    MsgBox "No new files"
Else
    MsgBox msg
End If
Set fso = Nothing
End Sub

Answer 1

Try the next adapted code, please:

Sub LookForNew()
 Dim FSO As Object, fils As Object, fil As Object, msg As String

 Set FSO = CreateObject("Scripting.FileSystemObject")
 Set fils = FSO.GetFolder(ThisWorkbook.Path).Files
 For Each fil In fils
    If Month(fil.DateLastModified) = Month(Date) And _
            Year(fil.DateLastModified) = Year(Date) Then
        msg = msg & fil.Name & vbTab & _
                            fil.DateLastModified & vbCrLf
    End If
 Next fil
 If msg = "" Then
    MsgBox "No new files"
 Else
    MsgBox msg
 End If
 Set FSO = Nothing
End Sub

You asked for "all files are modified the same month" and your code checks the creation date. Mine, checks what you asked...

In order to avoid returning the modified files for the same month of previous year, the year must also be checked.