在 Excel 的二维列表中查找值并找到最后一个实例

Question

I am in need of some major assistance. I am trying to create a VBA function that will allow me to find the last five instances of a string in a 2-D set of data and return the name of the column that each instance is in.

I have a data workbook which looks like this: picture of data worksheet

Essentially, every day every employee has a different placement and we input their names into this sheet. On a separate sheet, pictured below, the name of the employee is entered and their percentages and last 5 placements are shown. I can do simple things in VBA like making functions and the like, however I have no idea how to go about this beast. Any help would be much appreciated. Picture of Percentages page

data page with info: link

Answer 1

I think this should do it: I was interested to investigate it as some of the microsoft docs/functionality around FindNext I think might be bugged.

The function takes as a parameter the name of the person and a range of all the logged palcements. It returns an array of 5 columns so you'll need to familiarise yourself with ctrl-shift-enter for array functions

eg Formula for b13:f13 is =find_last_5(A13, $A$3:$G$10)

Option Explicit

Function find_last_5(ByVal employee_name As String, ByRef placement_data As Range)
  
  Const number_placements_required = 5
' return array
  Dim placements() As Variant
'redim to required size (1 row by 5 columns)
  ReDim placements(0, number_placements_required - 1)
  Dim i As Long
' initialise return array to #n/a
  For i = 0 To number_placements_required - 1
    placements(0, i) = CVErr(xlErrNA)
  Next i
  
  i = 0
  Dim first_found As String
  Dim found As Range
  
  With placement_data
'search passed array, backwards looking along rows from last/bottom row cell towards the top left
      Set found = .Find(what:=employee_name, _
        after:=placement_data.Range("a1"), _
        LookIn:=xlValues, _
        SearchDirection:=xlPrevious, _
        SearchOrder:=xlByRows)
      
      If Not found Is Nothing Then
          first_found = found.Address
          Do
              placements(0, i) = found.Column
              Set found = .Find(what:=employee_name, _
                after:=found, _
                LookIn:=xlValues, _
                SearchDirection:=xlPrevious, _
                SearchOrder:=xlByRows)
              i = i + 1
              
' do until 5 found or nothing found or we wrap back to first address found
          Loop While i < number_placements_required And _
          Not found Is Nothing _
          And found.Address <> first_found
      End If
  End With
  
  find_last_5 = placements

End Function