如何在哈希中查找所有键在Perl中具有值

Question

您如何确定所有哈希键是否都具有某些值？

Answer 1

From perldoc -f exists :

               print "Exists\n"    if exists $hash{$key};
               print "Defined\n"   if defined $hash{$key};
               print "True\n"      if $hash{$key};

               print "Exists\n"    if exists $array[$index];
               print "Defined\n"   if defined $array[$index];
               print "True\n"      if $array[$index];

A hash or array element can be true only if it's defined, and defined if it exists, but the reverse doesn't necessarily hold true.

Answer 2

Feed the result of keys into grep with defined

my @keys_with_values = grep { defined $hash{$_} } keys %hash;

Rereading your question, it seems like you are trying to find out if any of the values in your hash are undefined, in which case you could say something like

my @keys_without_values = grep { not defined $hash{$_} }, keys %hash;
if (@keys_without_values) {
    print "the following keys do not have a value: ",
        join(", ", @keys_without_values), "\n";
}

Answer 3

如果键存在，则它具有一个值（即使该值是undef ），因此：

my @keys_with_values = keys %some_hash;

Answer 4

Your question is incomplete thus this code can be answer ;-)

my %hash = (
    a => 'any value',
    b => 'some value',
    c => 'other value',
    d => 'some value'
);
my @keys_with_some_value = grep $hash{$_} eq 'some value', keys %hash;

EDIT: I had reread question again and decided that answer can be:

sub all (&@) {
  my $pred = shift();
  $pred->() or return for @_;
  return 1;
}

my $all_keys_has_some_value = all {$_ eq 'some value'} values %hash;

Answer 5

If all you want is to know if all values are defined, or any undefined this will do that:

sub all_defined{
  my( $hash ) = @_;
  for my $value ( values %$hash ){
    return '' unless defined $value; # false but defined
  }
  return 1; #true
} 

Answer 6

Here's one more way, using each . TIMTOWDI

 while (my($key, $value) = each(%hash)) {
      say "$key has no value!" if ( not defined $value);
 }