Excel VBA：如何根据数据库名称对行进行分组并根据特定的组名称添加值？

Question

I have a database in the sheet called "Database" as below: Column A refers to the specific type of data and B refers to the group. For example, X-1 is part of X so it's grouped as X and so forth.

Sheet "Database"

A	B
X-1	X
X-2	X
X-3	X
X-4	X
Y-1	Y
Y-2	Y
Y-3	Y
Z-1	Z
Z-2	Z
Z-3	Z

Next, I have another set of tables in the "Tables" sheet. So far, only columns A, B, and C exist, but I want to fill in the values in column D and E using the database dictionary above. Column A is the type of data, B is the block number, and C is the value of A. D will be the group of column A and E will be the sum of all data in for each group within that block number.

Sheet "Table"

| A | B | C |D|E
|:---- |:------:| -----:| -----:| -----:|
| X-1  |  Block 1    | 50 ||
| X-2  | Block 1    | 10 ||
| X-3  | Block 1    | 35 ||
| Y-1  | Block 1    | 45 ||
| Z-1  | Block 1    | 15 ||
| Y-2  | Block 1    | 5 ||
| X-4  | Block 1    | 50 ||
|  | Block 1 Total    | 210 |

I ultimately want to make my tables look like the below. It's important that the group data in column D comes at the beginning. Also, please note that sometimes the data in A are not in order. For example, Y-2 comes after Z-1.

A	B	C	D	E
X-1	Block 1	50	X	145
X-2	Block 1	10
X-3	Block 1	35
Y-1	Block 1	45	Y	50
Z-1	Block 1	15	Z	15
Y-2	Block 1	5
X-4	Block 1	50
	Block 1 Total	210

A	B	C	D	E
X-1	Block 2	10	X	80
X-2	Block 2	70
Y-1	Block 2	15	Y	20
Y-2	Block 2	5
Z-1	Block 2	100	Z	600
Z-2	Block 2	200
Z-3	Block 2	300
	Block 2 Total	700

So far my script looks like this:

    Dim lastrow As Integer
    Dim cell As Range
    Dim i, J, K As Integer
    Dim NumRows As Integer
    
    lastrow = Worksheets("Table").Range("A" & Rows.Count).End(xlUp).Row
    NumRows = Worksheets("Database").Range("A2").End(xlDown).Row
    
    For i = lastrow To 2 Step -1
    
            FundName_T = Worksheets("Table").Range("A" & i).Value
    
            For K = 2 To NumRows
                FundName_D = Worksheets("Database").Range("A" & K).Value
        
        If Cells(i, "A") <> "" And FundName_T = FundName_D Then
            GroupName = Worksheets("Database").Range("B" & K).Value
            Cells(i, "H") = GroupName
    
        End If
    
            Next K
    Next i

The above will make the table look like this:

A	B	C	D	E
X-1	Block 2	10	X
X-2	Block 2	70	X
Y-1	Block 2	15	Y
Y-2	Block 2	5	Y
Z-1	Block 2	100	Z
Z-2	Block 2	200	Z
Z-3	Block 2	300	Z
	Block 2 Total	700

Can someone please help?

Answer 1

You can do this using Power Query , available in Windows Excel 2010+ and Office 365.

• Ensure your data is in "Tables" and that you have the Names of those tables
  • I assumed, as you show, that your Table columns do not have headers.
  • That being the case, the system will add headers with names like Column n
• Select some cell in one of the tables and Data => Get&Transform => from Table/Range
• When the PQ UI opens, navigate to Home => Advanced Editor and paste the M Code below into that window
• Replace the table names in Lines 2 and 3 of the code with the appropriate names for your tables on your Database and Table sheets ( and the order is important )
• Examine the Applied Steps window and the comments to understand the methodology.

M Code

let

//Change table names to your actual table names
    Source = Excel.CurrentWorkbook(){[Name="Database"]}[Content],
    Source2 = Excel.CurrentWorkbook(){[Name="Table"]}[Content],

//Remove Block Totals
//It will be easier to just calculate them later
    #"Filtered Rows" = Table.SelectRows(Source2, each ([Column1] <> null and [Column1] <> "")),

//Join with Group Column to match up with Column1
//then expand the nested join
    grpCol = Table.AddJoinColumn(#"Filtered Rows","Column1",Source,"Column1","with Group"),
    #"Expanded with Group" = Table.ExpandTableColumn(grpCol, "with Group", {"Column2"}, {"with Group.Column2"}),

//Rename columns for clarity
    #"Renamed Columns" = Table.RenameColumns(#"Expanded with Group",{
        {"Column1", "Part"}, 
        {"Column2", "Block"}, 
        {"Column3", "Units"}, 
        {"with Group.Column2", "Group"}
        }),

//Group by "Block" and "Group"
//Calculate Subtotal for each Group (within each Block)
//Add Index column to subTable -- to be used so Group Name and Total for group only appear on first line
    #"Grouped Rows" = Table.Group(#"Renamed Columns", {"Block", "Group"}, {
            {"Amt", each List.Sum([Units]), type number}, 
            {"All", each _, type table [Part=text, Block=text, Units=number, Group=text]},
            {"Idx", each Table.AddIndexColumn(_,"Index",0,1)}
            }),

//Remove unneeded column of tables and Expand the column of tables with Index column added
    #"Removed Columns1" = Table.RemoveColumns(#"Grouped Rows",{"All"}),
    #"Expanded Idx" = Table.ExpandTableColumn(#"Removed Columns1", "Idx", {"Part", "Units", "Index"}, {"Part", "Units", "Index"}),

//Add columns for Group and Group Total, showing only on the first entry of the Group Name
//then remove unneeded columns
    #"Added Custom1" = Table.AddColumn(#"Expanded Idx", "Group.1", each if [Index] = 0 then [Group] else null),
    #"Added Custom2" = Table.AddColumn(#"Added Custom1", "Group Total", each if [Index] = 0 then [Amt] else null),
    #"Removed Columns" = Table.RemoveColumns(#"Added Custom2",{"Group", "Amt", "Index"}),

#"Renamed Columns1" = Table.RenameColumns(#"Removed Columns",{{"Group.1", "Group"}}),

//Group by Block
//Add Block subtotal row to each block group
    #"Grouped Rows1" = Table.Group(#"Renamed Columns1", {"Block"}, {
        {"blockGroup", each _, type table [Block=text, Part=text, Units=number, Group=nullable text, Group Total=nullable number]},
        {"Block Total", each Table.InsertRows(_, Table.RowCount(_),
            {[Block=null, Part=[Block]{0} & " Total", Units=List.Sum([Units]), Group=null,Group Total=null]})}       
        }),

//Remove unneeded column and expand the table
    #"Removed Columns3" = Table.RemoveColumns(#"Grouped Rows1",{"blockGroup", "Block"}),
    #"Expanded Block Total" = Table.ExpandTableColumn(#"Removed Columns3", "Block Total", {"Block", "Part", "Units", "Group", "Group Total"}, {"Block", "Part", "Units", "Group", "Group Total"})
in
    #"Expanded Block Total"

Database

Table

Results

If you require the Results Part column to be sorted in the same order as the original table, that can be done, but would require extra steps