CMake 共享库来自 object 库和 DLL 导出

Question

Background

I use cmake to build an open-source library .

The project is setup to do the following:

• Build a cmake OBJECT library named gpds-objs
• Build a STATIC library named gpds-static from gpds-objs
• Build a SHARED library named gpds-shared from gpds-objs

Furthermore, I'm using cmake's generate_export_header() to generate the necessary export macros.

The relevant parts of the cmake script looks like this:

# Set project information
project(gpds
    VERSION 1.0.0
    LANGUAGES CXX
    HOMEPAGE_URL "https://gpds.simulton.com"
)

# Some bacis cmake configuration
set(CMAKE_INCLUDE_CURRENT_DIR ON)
set(CMAKE_INCLUDE_CURRENT_DIR_IN_INTERFACE ON)

# List of private source files
set(SOURCES_PRIVATE
    # ...
)

# List of private header files
set(HEADERS_PRIVATE
    # ...
)

# List of public header files
set(HEADERS_PUBLIC
    # ...
)

# Define targets
set(NAME gpds)
set(TARGET-OBJS   ${NAME}-objs)
set(TARGET-STATIC ${NAME}-static)
set(TARGET-SHARED ${NAME}-shared)


################################################################################
# Object library                                                               #
################################################################################

add_library(${TARGET-OBJS} OBJECT)

target_compile_features(
    gpds-objs
    PUBLIC
        cxx_std_17
)

target_sources(
    ${TARGET-OBJS}
    PRIVATE
        ${SOURCES_PRIVATE}
        ${HEADERS_PRIVATE}
)

target_include_directories(
    ${TARGET-OBJS}
    INTERFACE
        $<BUILD_INTERFACE:${CMAKE_CURRENT_LIST_DIR}/include>
    PRIVATE
        $<BUILD_INTERFACE:${CMAKE_CURRENT_LIST_DIR}/include/gpds>
)


################################################################################
# Shared library                                                               #
################################################################################

add_library(${TARGET-SHARED} SHARED)

target_link_libraries(
    ${TARGET-SHARED}
    PUBLIC
        gpds-objs
)

target_compile_definitions(
    ${TARGET-SHARED}
    PRIVATE
        gpds_shared_EXPORTS     # We're building this library!
)


################################################################################
# Static library                                                               #
################################################################################

add_library(${TARGET-STATIC} STATIC)

target_link_libraries(
    ${TARGET-STATIC}
    PUBLIC
        gpds-objs
)

target_compile_definitions(
    ${TARGET-STATIC}
    PUBLIC
        GPDS_STATIC_DEFINE
)

# Common library properties
set_target_properties(
    ${TARGET-OBJS}
    ${TARGET-STATIC}
    ${TARGET-SHARED}
    PROPERTIES
        OUTPUT_NAME "gpds"
        ARCHIVE_OUTPUT_NAME "gpds"
        VERSION ${PROJECT_VERSION}
        POSITION_INDEPENDENT_CODE 1
)



################################################################################
# Export header                                                                #
################################################################################

include(GenerateExportHeader)
generate_export_header(
    ${TARGET-SHARED}
    BASE_NAME gpds
    EXPORT_FILE_NAME gpds_export.hpp
    DEPRECATED_MACRO_NAME "GPDS_DEPRECATED"
    NO_DEPRECATED_MACRO_NAME "GPDS_NO_DEPRECATED"
    EXPORT_MACRO_NAME "GPDS_EXPORT"
    NO_EXPORT_MACRO_NAME "GPDS_NO_EXPORT"
    STATIC_DEFINE "GPDS_STATIC_DEFINE"
    DEFINE_NO_DEPRECATED
)

A class definition within the library looks like this:

#include "gpds_export.hpp"

namespace gpds
{
    class GPDS_EXPORT container
    {
        // ...
    };
}

For completeness, here's the relevant part of gpds_export.hpp which gets generated by cmake's generate_export_header() :

#ifdef GPDS_STATIC_DEFINE
#  define GPDS_EXPORT
#  define GPDS_NO_EXPORT
#else
#  ifndef GPDS_EXPORT
#    ifdef gpds_shared_EXPORTS
        /* We are building this library */
#      define GPDS_EXPORT __declspec(dllexport)
#    else
        /* We are using this library */
#      define GPDS_EXPORT __declspec(dllimport)
#    endif
#  endif

#  ifndef GPDS_NO_EXPORT
#    define GPDS_NO_EXPORT 
#  endif
#endif

The problem

The problem I'm running into is when building gpds-objs I am presented with the following messages:

C:\Users\joel\Documents\projects\gpds\lib\src\value.cpp:7:1: warning: 'gpds::value::value(const gpds::value&)' redeclared without dllimport attribute: previous dllimport ignored [-Wattributes]
    7 | value::value(const value& other) :
      | ^~~~~
C:\Users\joel\Documents\projects\gpds\lib\src\value.cpp:17:1: warning: 'gpds::value::value(gpds::value&&)' redeclared without dllimport attribute: previous dllimport ignored [-Wattributes]
   17 | value::value(value&& other) :
      | ^~~~~
C:\Users\joel\Documents\projects\gpds\lib\src\value.cpp:25:1: warning: 'virtual gpds::value::~value()' redeclared without dllimport attribute: previous dllimport ignored [-Wattributes]
   25 | value::~value() noexcept
      | ^~~~~
C:\Users\joel\Documents\projects\gpds\lib\src\value.cpp:33:6: warning: 'void gpds::value::from_string(std::string&&)' redeclared without dllimport attribute: previous dllimport ignored [-Wattributes]
   33 | void value::from_string(std::string&& string)

I am unsure how to solve this properly.

From what I understand the problem is that building the gpds-objs target does not define any of the relevant export macros (neither GPDS_STATIC_DEFINE nor gpds_shared_EXPORTS ). Therefore, GPDS_EXPORT gets defined to __declspec(dllimport) which is incorrect as we're not building a shared library with the gpds-objs target.

One solution I can think of is defining gpds_shared_EXPORTS on the gpds-objs target instead of the gpds-shared target. However, this would mean that it's also defined when building the gpds-static target. This might be fine as long as gpds-static defines GPDS_STATIC_DEFINE .

What is the correct way of handling this?

Answer 1

You cannot use the same OBJECT library both for shared and static libraries.

An OBJECT library determines how the source files should be compiled. But source files should be compiled differently for a static and for a shared libraries.

Documentation for GenerateExportHeader describes, how the same generated header file could be used for static and shared libraries:

add_library(shared_variant SHARED ${lib_SRCS})
add_library(static_variant ${lib_SRCS})
generate_export_header(shared_variant BASE_NAME libshared_and_static)
set_target_properties(static_variant PROPERTIES
  COMPILE_FLAGS -DLIBSHARED_AND_STATIC_STATIC_DEFINE)

Here the export header is generated for the shared library , and the static library has additional compile definition for reuse that header. Note again, that different compile options, used for shared and static libraries, mean that you cannot reuse object files between these libraries. You could only reuse sources .