动态过滤器参数如何使用Query、importrange和indirect一起使用？ 或者可以完成任务的东西

Question

So I'm not sure if I just am not asking the right question while I've been searching for this answer.

But I'm wishing to change the date and time perimeters to the date and time that is input into a different cell.

=query(importrange("URL", "SEA:A1,CS"), "SELECT Col61, Col97, Col60, Col51, Col50, Col42, Col43, Col49, Col38, Col44: Col41 WHERE (Col3 >= datetime '2021-04-21 21:00:00' AND Col3 <= datetime '2021-4-21 21:50,00') AND ((Col93 = 501)) AND (lower(Col60) contains 'goalie') Order by Col61 desc", TRUE)

Other cells date and time 2021-05-06 21:10:00 and 2021-05-06 22:00:00

Result

=query(importrange"URL", "SEA:A1,CS"), "SELECT Col61, Col97, Col60, Col51, Col50, Col42, Col43, Col49, Col38, Col44: Col41 WHERE (Col3 >= datetime '2021-05-06 21:10:00' AND Col3 <= datetime '2021-05-06 22:00,00') AND ((Col93 = 501)) AND (lower(Col60) contains 'goalie') Order by Col61 desc", TRUE)

So apparently my question was some how viewed as not clear enough, so ill use a scenario.

I have Two separate sheets, Spreadsheet(A) and Spreadsheet(b). I am using Query with importrange(see above if clarification is needed) to Generate a certain set of values from Spreadsheet(A) Sheet1 to Spreadsheet(B) Sheet1.

Now in Spreadsheet(B) sheet1 there will two cells dedicated for date entries, lets go with A1 and B1. The purpose of these two dates, is to narrow the the data being imported to a specific time frame that is needed by the user.

Something like this With A1 and B1 blank

  =query(importrange("url", "Sheet1!A1:Z10"), "select Col1, Col2, Col3 where (Col1 > A1 and Col1 < B1)")

Then with 01-01-1111 11:11:11 in A1 abd 02-02-2222 22:22:22 in B2 the function would then change its parameters to

  =query(importrange("url", "Sheet1!A1:Z10"), "select Col1, Col2, Col3 where (Col1 > 1111-01-01 11:11:11 and Col1 < 2222-02-02 22:22:22)")

Also i would like to add i attempted to use the INDIRECT function, which worked fine when using query in the same spreadsheet, but would not work when using importrange to query from a different spreadsheet.

If its not clear enough what my question is, can i be given a clear explanation to some how make it more clear?

Answer 1

if your question is "how to query your data from spreadsheet A depending on dates in spreadsheet B while you are on spreadsheet C" then first you need to run every IMPORTRANGE formula separately to allow access to your spreadsheets A and B. then you can try:

=QUERY({IMPORTRANGE("URL A"; "SEA!A1:CS")}; 
 select Col61,Col97,Col60,Col51,Col50,Col42,Col43,Col49,Col38,Col44,Col41
 where Col3 >= datetime '"&TEXT(IMPORTRANGE("URL B"; "Sheet1!A1"); "yyyy-mm-dd hh:mm:ss")&"' 
   and Col3 <= datetime '"&TEXT(IMPORTRANGE("URL B"; "Sheet1!B1"); "yyyy-mm-dd hh:mm:ss")&"' 
   and Col93 = 501 
   and lower(Col60) contains 'goalie' 
 order by Col61 desc"; 1)

---

update

=UNIQUE(QUERY(IMPORTRANGE("18AuN0rkrjUe0qK5ATS_MojgK49l5q6wf2nAMVEp54E4", A2&"!A1:FC1000"), 
 "select Col159,Col61,Col97,Col60,Col73,Col66,Col83,Col91,Col78,Col77,Col84,Col75,Col67,Col72,Col92,Col76,Col71,Col69,Col81 
  where Col93 = 501 
    and not lower(Col60) contains 'goalie'
    and Col159 >= datetime '"&TEXT(A3, "yyyy-mm-dd hh:mm:ss")&"'
    and Col159 <= datetime '"&TEXT(A4, "yyyy-mm-dd hh:mm:ss")&"' 
  order by Col3 desc
  label Col159'timestamp'", 1))