如何使用数据转储器将简单的 hash 存储在 perl 中

Question

%hash = ('abc' => 123, 'def' => [4,5,6]);

how can I store above hash in file using data dumper in Perl

Answer 1

Files can only contain sequences of bytes, so you need to convert the data structure into a sequence of bytes somehow. This process is called serialization.

The possibilities available to you are endless, but a few are worth mentioning:

• JSON is a very common choice.
• YAML is more flexible.
• Storable is specifically made for Perl data structures.

There is also Data::Dumper, as you say.

use Data::Dumper qw( );

sub serialize {
   my ($x) = @_;
   local $Data::Dumper::Purity = 1;    # Required for some data structures.
   local $Data::Dumper::Useqq = 1;     # Optional. Limits output to ASCII.
   local $Data::Dumper::Sortkeys = 1;  # Optional. Makes revision control easier.
   return Data::Dumper->Dump([$x], ["x"]);
}

print($fh serialize($x));

Data::Dumper isn't a particularly good choice, since there's no existing module to safely deserialize the structure in Perl ^[1] , and there's even less support outside of Perl.

sub deserialize {
   my ($s) = @_;
   my $x;
   eval($s);       # XXX Unsafe!
   die($@) if $@;
   return $x;
}

---

1. If you're ok with limiting yourself to data structure JSON can serialize (by setting Purity to 0 ), then you could use Data::Undump to safely deserialize. But then why not just use JSON?!

Answer 2

use Data::Dumper open (FL, ">", "file.txt") or die "Cant open file $! "; print FL Dumper \%hash; close FL;

Answer 3

"how can I store above hash in file using data dumper in Perl"

Store it as JSON so it can be read back by (almost) anything, using Data::Dumper configured to print JSON.

use strict;
use warnings;
use Data::Dumper;

local $Data::Dumper::Pair = ' : ';
local $Data::Dumper::Quotekeys = 1;
local $Data::Dumper::Useqq = 1;
local $Data::Dumper::Terse = 1;

my %hash = ('abc' => 123, 'def' => [4,5,6]);

open my $file, '>', 'foo.json' or die $!;

print $file Dumper \%hash;

Output:

$ cat foo.json
{
  "def" : [
             4,
             5,
             6
           ],
  "abc" : 123
}

(Note: I would of course rather use a dedicated JSON-handling module for this, but you asked....)