使用 VBA 向 Word 文档添加连续信息

Question

I am trying to add information from Excel to Word using VBA and at the same time add text/paragraphs to that word doc.

I have the below code which for some reason is resulting in the table note being added. I want to add tables and then content consecutively.

Tried to play with the paragraph numbers but with no success?

Qualifier - I am new to VBA and not sure I am doing this right.

Here is my code:

Sub create_Word()
  
Dim tblRange As Excel.Range
Dim WrdRange As Word.Range
Dim WordApp As Word.Application
Dim WordDoc As Word.Document
Dim WordTable As Word.Table
Dim intRows
Dim intColumns

'Define number of rows
intNoOfRows = 2
intNoOfColumns = 2

' Check if word is open, otherwise open word

On Error Resume Next
Set WordApp = GetObject(class:="Word.Application")
If WordApp Is Nothing Then Set WordApp = CreateObject(class:="Word.Application")

' Make word visible and activate the program
WordApp.Visible = True
WordApp.Activate

' Create document inside word

Set WordDoc = WordApp.Documents.Add

'Section 1

With WordApp.Selection
        
    .Paragraphs.Alignment = wdAlignParagraphLeft
    .Font.Size = 12
    .TypeText "Heading" & vbCrLf & vbCrLf & "Date: _____________" & vbCrLf & vbCrLf
    .BoldRun
    .Font.Size = 12
    .TypeText "Content" & vbCrLf
    .TypeText "Period ended: 31 December 2020" & vbCrLf & vbCrLf
    .BoldRun
    
End With
     
'Add table

Set WrdRange = WordDoc.Paragraphs(11).Range
WordDoc.Tables.Add WrdRange, intNoOfRows, intNoOfColumns
Set WordTable = WordDoc.Tables(1)
WordTable.Borders.Enable = True


End Sub

UPDATE Based on the suggestions below, I've adapted the code and this results in the tables combining for some reason. The following code has been applied:

Set WordDoc = WordApp.Documents.Add

'Section 1

With WordApp.Selection
        
    .Paragraphs.Alignment = wdAlignParagraphLeft
    .Font.Size = 12
    .TypeText "Test Text 1"
    
End With
     
'Add table 1

Set WrdRange = WordDoc.Paragraphs.Last.Range
Set WordTable = WordDoc.Tables.Add(WrdRange, intNoOfRows, intNoOfColumns)
WordTable.Borders.Enable = True

'Section 2
With WordApp.Selection
   .TypeText "Test Text 2" & vbCrLf
       
End With

'Add table 1

Set WrdRange = WordDoc.Paragraphs.Last.Range
Set WordTable = WordDoc.Tables.Add(WrdRange, intNoOfRows, intNoOfColumns)
WordTable.Borders.Enable = True

Answer 1

Your first problem is that you have not reset error handling after getting the Word application. That section of code should be:

On Error Resume Next
Set WordApp = GetObject(class:="Word.Application")
If WordApp Is Nothing Then Set WordApp = CreateObject(class:="Word.Application")

On Error GoTo 0

You are attempting to add a table to paragraph 11, but on my count your document only contains 8 paragraphs. If you are trying to add the table to the end of the document then you can use either:

Set WrdRange = WordDoc.Paragraphs.Last.Range

or:

Set WrdRange = WordDoc.Characters.Last

The Add method is a function and will return the object added so you should make use of that, eg

Set WordTable = WordDoc.Tables.Add(WrdRange, intNoOfRows, intNoOfColumns)
WordTable.Borders.Enable = True

or:

With WordDoc.Tables.Add(WrdRange, intNoOfRows, intNoOfColumns)
    .Borders.Enable = True
End With

You code also includes some undeclared variables. You can avoid these errors by adding Option Explicit at the top of the code module. This will prevent your code from compiling when you have undeclared variables. To add this automatically to new modules open the VBE and go to Tools | Options. In the Options dialog ensure that Require Variable Declaration is checked.

EDIT:

Stop using Selection . There is rarely any need to select anything when working with either Word or Excel.

Your tables are getting joined because they follow each other. This is because you are using Selection to add text, even though the current selection is before the table.

Change:

With WordApp.Selection
   .TypeText "Test Text 2" & vbCrLf
       
End With 

To:

WordDoc.Paragraphs.Last.Range.Text = "Test Text 2" & vbCr

Make yourself familiar with the help tools you have in the VBE: Intellisense, the Object Browser and online help.