如何将我们的 ERC20 代币作为我们产品的费用？

Question

I have one product if the consumer want to buy my product he needs to pay 50 ERC20 Tokens. how to write this smart contract and how to know that he payed my tokens only ?

Answer 1

First, the user needs to manually approve your contract to spend their tokens by executing the approve() function on the token contract. This is a security measure, and you can read more about the reasoning behind it in this answer or this other answer .

Then, your contract can call the token contract's transferFrom() function, passing it arguments stating that you want to transfer tokens from the user, to your contract address.

If the transfer not successful (the user has not approved your contract to spend their tokens or didn't have enough tokens to perform the transfer), the token contract should return false from the transferFrom() function, so you can validate the return value in a require() condition for example.

pragma solidity ^0.8;

interface IERC20 { // defining an interface of the (external) token contract that you're going to be interacting with
    function decimals() external view returns (uint8);
    function transferFrom(address _from, address _to, uint256 _amount) external returns (bool);
}

contract MyContract {
    function buy() external {
        IERC20 tokenContract = IERC20(address(0x123)); // the token contract address

        // reverts if the transfer wasn't successful
        require(
            tokenContract.transferFrom(
                msg.sender, // from the user
                address(this), // to this contract
                50 * (10 ** tokenContract.decimals()) // 50 tokens, incl. decimals of the token contract
            ) == true,
            'Could not transfer tokens from your address to this contract' // error message in case the transfer was not successful
        );
        
        // transfer was successful, rest of your code
    }
}