如何查找除文件所有者名称中具有特定子字符串的文件之外的所有文件

Question

I'm trying to find all files from a certain path except the files owned by users who have "developer" or "admin" within their user name. Can anyone help me achieve this?

I am using the find command to find files. Tried doing this using the -user argument but it failed.

find [pathname] -type f -not -user "*admin*"

I am also tasked with finding all files where the owner name of the file represents an integer (The owner name is a string, but represents an integer). I know isdigit() returns true if a string represents a positive integer. Would anyone know how to achieve this as well? Thanks.

Answer 1

I don't think you can do it directly with find , because -user does a straight up equality comparison, not wildcard or regular expression matching.

A quick perl script that does the job (Pass directory names to search on the command line):

#!/usr/bin/env perl
use strict;
use warnings;
use File::Find;
use File::stat;
use User::pwent;
use feature qw/say/;

my %uids; # Cache user information

sub wanted {
    my $st = stat($File::Find::name) or
        (warn "Couldn't stat $File::Find::name: $!\n" && return);
    return unless -f $st; # Only look at regular files
    my $user =
        exists $uids{$st->uid} ? $uids{$st->uid} : $uids{$st->uid} = getpwuid($st->uid);
    # Print filenames owed by uids that don't include developer
    # or admin in a username
    say $File::Find::name if !defined $user || $user->name !~ /developer|admin/;
    # Or defined $user && $user->name =~ /^\d+/ for filtering to usernames that are all digits
    # Or just !defined $user for files owned by uids that don't have /etc/passwd entries
}

find(\&wanted, @ARGV);

---

Avoiding perl , hmm...

find pathname -type f -printf "%u\037%p\036" | awk -F"\037" -v RS="\036" '$1 !~ /developer|admin/ { print $2 }'

will find files except ones owned by the developer and admin accounts, but for the second part, you can't tell a user id that doesn't have a name apart from a name that's all digits with this approach.