使用 bash 组合来自多个文本文件的数字

Question

I'm strugling to combine some data from my txt files generated in my jenkins job.

on each of the files there is 1 line, this is how each file look:

testsuite name="mytest" cars="201" users="0" bus="0" bike="0" time="116.103016"

What I manage to do for now is to extract the numbers for each txt file:

awk '/<testsuite name=/{print $3, $4, $5, $6}' my-output*.txt 

Result are:

cars="193" users="2" bus="0" bike="0"
cars="23" users="2" bus="10" bike="7"
cars="124" users="2" bus="5" bike="0"
cars="124" users="2" bus="0" bike="123"

now I have a random number of files like this:

my-output1.txt
my-output2.txt
my-output7.txt
my-output*.txt

I would like to create single command just like the one I did above and to sum all of the files to have the following echo result:

cars=544 users=32 bus=12 bike=44

is there a way to do that? with a single line of command?

Answer 1

1st solution: With your shown samples please try following awk code, using match function in here. Since awk could read multiple files within a single program itself and your files have .txt format you can pass as .txt format to awk program itself.

Written and tested in GNU awk with its match function's capturing group capability to create/store values into an array to be used later on in program.

awk -v s1="\"" '
match($0,/[[:space:]]+(cars)="([^"]*)" (users)="([^"]*)" (bus)="([^"]*)" (bike)="([^"]*)"/,tempArr){
   temp=""
   for(i=2;i<=8;i+=2){
     temp=tempArr[i-1]
     values[i]+=tempArr[i]
     indexes[i-1]=temp
   }
}
END{
   for(i in values){
     val=(val?val OFS:"") (indexes[i-1]"=" s1 values[i] s1)
   }
   print val
}
' *.txt

Explanation:

• In start of GNU awk program creating variable named s1 to be set to " to be used later in the program.
• Using match function in main program of awk .
• Mentioning regex [[:space:]]+(cars)="([^"]*)" (users)="([^"]*)" (bus)="([^"]*)" (bike)="([^"]*)" (explained at last of this post) which is creating 8 groups to be used later on.
• Then once condition is matched running a for loop which runs only even numbers in it(to get required values only).
• Creating array values with index of i and keep adding its own value + tempArr values to it, where tempArr is created by match function.
• Similarly creating indexes array to store only key values in it.
• Then in END block of this program traversing through values array and printing the values from indexes and values array as per requirement.

Explanation of regex:

[[:space:]]+       ##Matching spaces 1 or more occurrences here.
(cars)="([^"]*)"   ##Matching cars=" till next occurrence of " here.
 (users)="([^"]*)" ##Matching spaces followed by users=" till next occurrence of " here.
 (bus)="([^"]*)"   ##Matching spaces followed by bus=" till next occurrence of " here.
 (bike)="([^"]*)"  ##Matching spaces followed by bike=" till next occurrence of " here.

---

---

2nd solution: In GNU awk only with using RT and RS variables power here. This will make sure the sequence of the values also in output should be same in which order they have come in input.

awk -v s1="\"" -v RS='[[:space:]][^=]*="[^"]*"' '
RT{
  gsub(/^ +|"/,"",RT)
  num=split(RT,arr,"=")
  if(arr[1]!="time" && arr[1]!="name"){
    if(!(arr[1] in values)){
      indexes[++count]=arr[1]
    }
    values[arr[1]]+=arr[2]
  }
}
END{
  for(i=1;i<=count;i++){
     val=(val?val OFS:"") (indexes[i]"=" s1 values[indexes[i]] s1)
  }
  print val
}
' *.txt

Answer 2

Using awk

$ cat script.awk
BEGIN {
    FS="[= ]"
} {
    gsub(/"/,"")
    for (i=1;i<NF;i++) 
      if ($i=="cars") cars+=$(i+1)
        else if($i=="users") users+=$(i+1);
          else if($i=="bus") bus+=$(i+1); 
            else if ($i=="bike")bike+=$(i+1)
} END {
print "cars="cars,"users="users,"bus="bus,"bike="bike
}

To run the script, you can use;

$ awk -f script.awk my-output*.txt

Or, as a ugly one liner.

$ awk -F"[= ]" '{gsub(/"/,"");for (i=1;i<NF;i++) if ($i=="cars") cars+=$(i+1); else if($i=="users") users+=$(i+1); else if($i=="bus") bus+=$(i+1); else if ($i=="bike")bike+=$(i+1)}END{print"cars="cars,"users="users,"bus="bus,"bike="bike}' my-output*.txt 

Answer 3

found a way to do so a bit long:

awk '/<testsuite name=/{print $3, $4, $5, $6}' my-output*.xml | sed -e 's/[^0-9]/ /g' -e 's/^ *//g' -e 's/ *$//g' | tr -s ' ' | awk '{bus+=$1;users+=$2;cars+=$3;bike+=$4 }END{print "bus=" bus " users="users " cars=" cars " bike=" bike}'

M. Nejat Aydin answer was good fit:

awk -F '[ "=]+' '/testsuite name=/{ cars+=$5; users+=$7; buses+=$9; bikes+=$11 } END{ print "cars="cars, "users="users, "buses="buses, "bikes="bikes }' my-output*.xml

Answer 4

You can try rquery to do such query.

[ rquery]$ echo 'testsuite name="mytest" cars="201" users="0" bus="0" bike="0" time="116.103016"' > files/output1.txt
[ rquery]$ echo 'testsuite name="mytest" cars="201" users="1" bus="1" bike="2" time="116.103016"' > files/output2.txt
[ rquery]$ echo 'testsuite name="mytest" cars="301" users="10" bus="21" bike="23" time="116.103016"' > files/output3.txt
[ rquery]$ ./rq -q "p d/ /|s 'cars='+sum(trim(substr(@3,strlen('cars=')),'\"')),'users='+sum(trim(substr(@4,strlen('users=')),'\"')),'bus='+sum(trim(substr(@5,strlen('bus=')),'\"')),'bikes='+sum(trim(substr(@6,strlen('bikes=')),'\"'))" files/
cars=703        users=11        bus=22  bikes=25

Check out the latest rquery from here https://github.com/fuyuncat/rquery/releases

Answer 5

You may use this awk solution:

awk '{
   for (i=1; i<=NF; ++i)
      if (split($i, a, /=/) == 2) {
         gsub(/"/, "", a[2])
         sums[a[1]] +=a[2]
      }
}
END {
   for (i in sums) print i "=" sums[i]
}' file*

bus=15
cars=464
users=8
bike=130