将数组中的所有矩形相互合并

Question

I have an array of rectangles and I want to merge all overlapping and adjacent rectangles into each other. The final array should have no overlapping or adjacent rectangles. I tried doing the below code but some rectangles are still left over.

func combine_boxes(boxes: Array) -> void:
    var merged := true
    while merged:
        merged = combine_all_overlapping_box(boxes)


func combine_all_overlapping_box(boxes: Array) -> bool:
    var box: Rect2 = boxes[0]
    # Remove our box
    boxes.remove(0)
    # Start from the back of the the array so removals are easier and don't invalidate the index
    var merged := false
    for j in range(boxes.size()-1, -1, -1):
        var collider: Rect2 = boxes[j]
        if overlap_adjacent(box, collider):
            box = box.merge(collider)
            # Remove collider box
            boxes.remove(j)
            merged = true
    # Either add the merge box in, or the unaltered box we remove at the start
    boxes.append(box)
    return merged

Answer 1

This what I have been able to come up with:

func combine_rects(rects: Array) -> Array:
    var result := rects.duplicate()
    var merged := true
    while merged:
        merged = false
        rects = result
        result = []
        while rects.size() > 0:
            var current_rect:Rect2 = rects.pop_back()
            for index in for index in range(rects.size() - 1, -1, -1):
                var other_rect:Rect2 = rects[index]
                if current_rect.intersects(other_rect, true):
                    merged = true
                    current_rect = current_rect.merge(other_rect)
                    rects.remove(index)

            result.append(current_rect)

    return result

Let us look at the inner loop first:

var current_rect:Rect2 = rects.pop_back()
for index in for index in range(rects.size() - 1, -1, -1):
    var other_rect:Rect2 = rects[index]
    if current_rect.intersects(other_rect, true):
        merged = true
        current_rect = current_rect.merge(other_rect)
        rects.remove(index)

result.append(current_rect)

As you can see I remove an element from rects and store it in current_rect . Then iterate over the rest of the elements, comparing it with them. I use intersects with true as second argument so it also considers adjacent rects as intersecting… If they intersect, I merge them. And also remove the other element with rects.remove(index) … I iterate backwards so I don't have to adjust the index .

Since I set the current_rect with the result of the merge ( current_rect = current_rect.merge(other_rect) ), I can continue merging more rects into it in the same loop.

Finally I add whatever I ended up with to the result .

If we look at the mid loop, we see that I do this until I exhaust rects :

while rects.size() > 0:
    var current_rect:Rect2 = rects.pop_back()
    for index in for index in range(rects.size() - 1, -1, -1):
        var other_rect:Rect2 = rects[index]
        if current_rect.intersects(other_rect):
            merged = true
            current_rect = current_rect.merge(other_rect)
            rects.remove(index)

    result.append(current_rect)

Since I only remove from rects (either by pop_back or by remove ) it must eventually be empty and the loop ends.

Now look at the broader picture:

func combine_rects(rects: Array) -> Array:
    var result := rects.duplicate()
    var merged := true
    while merged:
        merged = false
        rects = result
        result = []
        while rects.size() > 0:
            var current_rect:Rect2 = rects.pop_back()
            for index in for index in range(rects.size() - 1, -1, -1):
                var other_rect:Rect2 = rects[index]
                if current_rect.intersects(other_rect):
                    merged = true
                    current_rect = current_rect.merge(other_rect)
                    rects.remove(index)

            result.append(current_rect)

    return result

We will continue looping as long as we merged something. The merged variable keeps track of that. I set it to true so the flow of execution enters the loop (the alternative would have been to make an infinite loop while true and use break ).

For the loop we need to make sure merged starts false , and result is empty. So we do that. But also, we want to iterate over the results of the past iteration. Which is why I set rects = result . And that means that I need the starting rects in result . I took the opportunity to work on a copy ( var result:= rects.duplicate() ).

You should be able to use it like this:

boxes = combine_rects(boxes)