如何在 F# 中打印用于调用此 function 的 function 参数名称

Question

How can I print argument function name that was used to call this function?

open System
open System.Threading.Tasks

let logger (f: ('a -> Task<'b>)) : ('a -> Task<'b>) =
    printfn "Hey: %O" (nameof f) // I would like to print "myFunc", not "f"
    f

let myFunc x = task {return x }

let d = (logger myFunc) 3

Answer 1

You could use the ReflectedDefinition(true) attribute, which automatically quotes the argument of a method call and gives you both the value (to use at runtime) and the code quotation from which you can (if the format is right) extract the name. This only seems to work with method calls though:

type Logger = 
  static member log([<ReflectedDefinition(true)>]f: Expr<('a -> Task<'b>)>) : ('a -> Task<'b>) =
    match f with 
    | Patterns.WithValue(v, _, Patterns.Lambda(_, Patterns.Call(_, mi, _))) ->
        printfn "Hello %s!" mi.Name
        unbox v
    | _ -> failwith "Wrong format"

let myFunc x = task {return x }

let d = (Logger.log myFunc) 3

The design and motivation of this is discussed in the F# 4.0 Speclet: Auto-Quotation of Arguments at Method Calls