Common Lisp 中的非矩形 arrays？ （用于教学目的的一般问题。）

Question

Simply for the sake of completeness I would like to know, whether there is a way to define "jagged" or "ragged arrays" in Common Lisp like it is described for Java eg here: https://www.geeksforgeeks.org/jagged-array-in-java/

Along with this question comes the second question, what is the advantage of such a definition of multidimensional arrays? More efficient memory allocation? Or is the idea of a "jagged array" itself problematic - at least in the Common Lisp context?

Until now, I only could find descriptions of the regular way of defining rectangular multidimensional arrays - or I overlooked the information I was searching for.

At this moment, I would imagine that in Common Lisp one would fill the not needed places with NIL or 0 or something like that in a regular multidimensional array, if the replication of such an asymmetric data field seems to be useful. ... Or I would manage three vectors of different length maybe by trying to define a custom structure with them.

If these are stupid ideas, is there any other way? Or is a "ragged array" in Java simply a nested vector with elements of different size in general - and a multidimensional array in Common Lisp also simply a nested vector with elements of equal size that comes along with some helpful abstractions for managing that regular structure?

I thank you very much for your response.

Answer 1

Since they are vectors of vectors they are easy to define. Example:

getter

(defun jref (jarray i j)
  (aref (aref jarray i) j))

setter

(defun (setf jref) (new-value jarray i j)
  (setf (aref (aref jarray i) j) new-value)) 

Make such an array: (make-jarray '(3 (5 6 2))

(defun make-jarray (dimensions &key (initial-element 0))
  (make-array
   (first dimensions)
   :initial-contents (loop for d in (second dimensions)
                           collect (make-array
                                    d
                                    :initial-element initial-element))))

Example:

CL-USER > (let ((ja1 (make-jarray '(4 (3 2 4 5)))))
            (setf (jref ja1 0 1) 'hello)
            (setf (jref ja1 3 4) 'world)
            (incf (jref ja1 2 0) 42)
            (values ja1
                    (jref ja1 2 0)))

#(#(0 HELLO 0) #(0 0) #(42 0 0 0) #(0 0 0 0 WORLD))
42