Combobox.dropdown in Excel 显示在用户表单之外

Question

I have created a userform and included a combobox populated with numbers 1 to x in userform.initialize and then added.setfocus and.dropdown commands. For some strange reason the combobox (with dropdown) appears on my lefthand screen outside the userform. The combobox also appears on the userform, but without the dropdown displayed. The screen combobox is active and if I click a number in the dropdown list the code accepts this input.

I have tried deleting the combobox and inserting another one with a different name, but the behaviour persists. If I remove the.dropdown command, the combobox appears correctly on the userform without the screen copy and I can click the userform box and display and use the dropdown list.

On reading an unrelated post, I tried adding.visible=false, followed by.visible=true before the.dropdown command, but that didn't stop the behaviour.

I have tried exporting, deleting and re-importing the userform, but the behaviour persists.

The code I am using (in userform_initialize sub) is:

With cbxGroup 'combobox
   .Clear
   For i = 1 To PlayGroups
   .AddItem i
   Next
   .ListIndex = -1
   .Visible = False
   .Visible = True
   .SetFocus
   .DropDown
End With

Has anyone come across such behaviour before and can explain what has happened, and maybe how to fix it. I can just recreate the userform, but it seems a lot of unnecessary work. I am using Office 365

Answer 1

I can confirm the behaviour.

I strongly assume that this is related to the fact that you are using the Initialize -Trigger. When this trigger is executed, the form is still in the creation-process and some internal properties (eg the exact screen position) are likely not calculated. As a consequence, when calling DropDown , the Combobox is painted on the screen but not at the right position.

You can keep the code to fill the combobox in the Initialize -Trigger, but you should move the SetFocus and DropDown -commands to the Activate -Trigger

Private Sub UserForm_Initialize()
    fillCombo
End Sub

Private Sub UserForm_Activate()
    showCombo
End Sub

Sub fillCombo()
    With Me.cbxGroup 
       .Clear
       Dim i
       For i = 1 To PlayGroups
           .AddItem i
       Next
       .ListIndex = -1
    End With
End Sub

Sub showCombo()
    With Me.cbxGroup 
       .SetFocus
       .DropDown
    End With
End Sub