在自定义公式中使用 MATCH 的条件格式不一致

Question

I have 2 cells A1 and B1 that contain the same values. I want to create a conditional formatting rule using the custom formula =MATCH(A1,B1) that colours both cells green.

This sometimes works on other cell pairs but other times it simply doesn't work.

Note that the cells have a custom number format that adds a letter and a semi-colon before the numbers.

Let me know what I am doing wrong.

3 pairs, 2 pairs worked, Q3 & R3 didn't:

My conditional formatting:

Answer 1

Relative References

The cell references in your rule are relative. This means that when the current cell is in a different row or column, the formula shifts accordingly. Changes in the current row don't affect your rule, but changes in the current column number, that are not that in multiples of 2, mean the MATCH function's range argument uses the wrong column.

You can see the behavior by putting =MATCH(Q3,R3,0) in Q4 and then copy it to R4 . The search_key argument will automatically update to R3 and the range argument to S3 . The new formula will be =MATCH(R3,S3,0) , but you need the range argument to be Q3 because R3 is in a right column: =MATCH(R3,Q3,0) . This same thing is taking place in your conditional formatting rule.

Corrected Rule

The following custom formula will work as expected. It adjusts based on whether the current cell is the left, or the right column, of a column pair.

"Apply to range"

M3:R55

"Custom formula is"

=MATCH(M3,OFFSET(M3,0,IF(ISODD(COLUMN($M3))=ISODD(COLUMN()),1,-1)),0)

Explanation

1. You have a contiguous range of column pairs, M3:R55 , where each pair is comprised of a left and a right column
2. If the MATCH function's search_key argument is from a left-column cell, then its range argument needs to be the cell OFFSET one column to the right of the search_key .
   • OFFSET(M3,0,1)
3. If the MATCH function's search_key argument is from a right-column cell, then its range argument needs to be the cell OFFSET one column to the left of the search_key .
   • OFFSET(M3,0,-1)
4. The very first column in the range is necessarily a left column. If that column is odd-numbered, all left columns will be odd-numbered. If that column is even-numbered, all left columns will be even-numbered.
5. Therefore, one test applying the ISODD function to the first column's number, and a second identical test on the current column, would necessarily both succeed or both fail if the current column is a left column.

Examples

# First Column is M, current cell is Q3

=ISODD(COLUMN($M3))=ISODD(COLUMN())
=ISODD(13)=ISODD(17)
=TRUE=TRUE
=TRUE        // current col is left


# First Column is M, current cell is R3

=ISODD(COLUMN($M3))=ISODD(COLUMN())
=ISODD(13)=ISODD(18)
=TRUE=FALSE
=FALSE      // current col is right


# First Column is N, current cell is R3

=ISODD(COLUMN($N3))=ISODD(COLUMN())
=ISODD(14)=ISODD(18)
=FALSE=FALSE
=TRUE       // current col is left

6. All that remains is to build the MATCH formula and use a comparison of the ISODD tests to determine whether to use 1 or -1 for the OFFSET function's range argument:

=MATCH(M3,OFFSET(M3,0,
  IF(ISODD(COLUMN($M3))=ISODD(COLUMN()),
    1,   // condition_true (current col is left)
    -1)) // condition_false (current col is right)
  ,0)