T-SQL从字符串中找到一个八个字符串，该字符串不包含空格并且至少包含一个数字，并将其排除在外

Question

The problem is we have many different error messages being produced and stored in a sql table within the error message there could be an occurance of a project number 8 characters long which would contain at least 1 number is alphanumeric and no spaces. per error message the project number may not be the same.

eg

'error found processing project: abcd12sf no funding is set'
'error found processing project: qd451srf no funding is set'
'error project 2344ddrf has no approver'

We want to be able to count the occurances of particular errors and so we need to strip the project number from the output

thus

'error found processing project: no funding is set' , 2 occurances
'error project has no approver' , 1 occurance

Any help is greatly appreciated

Answer 1

Start by creating a Function that returns the project number. I did this by finding the first integer and then position of the space after it, then counting back 8 characters you have the start and end position.

CREATE FUNCTION GetProjectNumber(@FullErrorMessage varchar(100))

RETURNS CHAR(8)

AS 

BEGIN

    DECLARE @ProjectNumber CHAR(8)

    SET @ProjectNumber = (
                                    SELECT  
                                    SUBSTRING(@FullErrorMessage, CHARINDEX(' ',@FullErrorMessage,PATINDEX('%[0-9]%',@FullErrorMessage))-8,8)
                                )

    RETURN @ProjectNumber
END

Alter your table to have a computed column called ProjectNumber here is the create I did for testing but you should get the idea.

CREATE TABLE T_Errors(
ID int IDENTITY(1,1),
ErrorMessage varchar(1024),
ProjectNumber AS (dbo.GetProjectNumber(ErrorMessage))
CONSTRAINT PK_T_Errors PRIMARY KEY CLUSTERED(ID))

Now you have the project number in a separate column it is easy to play with.

SELECT 
CleanErrorMessage = REPLACE(ErrorMessage,ProjectNumber,''),
COUNT(*) As ErrorCount
FROM T_Errors
GROUP BY REPLACE(ErrorMessage,ProjectNumber,'')

Answer 2

If you have a list of valid project numbers you can do something like this.

Sample tables and data:

declare @Project table
(
  ProjectNumber char(8)
)

insert into @Project values
('abcd12sf'),
('qd451srf'),
('2344ddrf')

declare @Error table
(
  Error varchar(100)
)

insert into @Error values
('error found processing project: abcd12sf no funding is set'),
('error found processing project: qd451srf no funding is set'),
('error project 2344ddrf has no approver')

The query:

select P.Error,
       count(*) as ErrorCount
from @Error as E
  cross apply
    (
      select replace(E.Error, P.ProjectNumber, '') as Error
      from @Project as P
      where E.Error like '%'+P.ProjectNumber+'%'
    ) as P
group by P.Error

Result:

Error                                               ErrorCount
--------------------------------------------------  ----------
error found processing project:  no funding is set  2
error project  has no approver                      1