从 Prolog 的列表中删除谓词

Question

I want to delete all predicates named a from the list. The result must be as shown below:

?- delete_all(a(_), [a(1),a(2),a(3),b(1)], R).
R = [b(1)]

Please, do not offer me built in solutions of SWI or others, because the code must be in Amzi-Prolog.

Thanks.

Edit: I have tried the following code but it is working properly only for atoms:

remove_all(X,[],[]).
remove_all(X,[X|L],R):-remove_all(X,L,R).
remove_all(X,[Y|L],R):-not(X=Y), remove_all(X,L,M), R=[Y|M].

?-remove_all(a(_), [a(1),a(2),a(3),b(1)], R).
R=[a(2),a(3),b(1)]

which is not true:(

Answer 1

use findall

findall(X, (member(X,[a(1),a(2),a(3),b(1)]),\+(X=a(_))) ,V).

Answer 2

I know you said no swi-prolog. However it's an easy task (compared to the main one), to implement a recursion that behaves the same as the exclude/3 used, the rest should be ISO prolog or present in amzi too. It useslambda.pl , a library that allows easier higher order programming:

:- [lambda].
filter(Term, List, Result) :-
    Term =.. [Pred|Args],
    length(Args, Arity),
    exclude(\X^(X =.. [Pred2|Args2],
                length(Args2, Arity2),
                Pred == Pred2,
                Arity == Arity2), List, Result).

This solution has the advantage of staying away from the unpure findall/3 .

Hope this helps.

Answer 3

Little fix, and it should work:

% remove_same_indicator(+Callable,+List,-List)
remove_same_indicator(_, [], []).
remove_same_indicator(X, [Y|L], R) :- 
       functor(X, F, N), 
       functor(Y, F, N), 
       !, 
       remove_same_indicator(X, L, R).
remove_same_indicator(X, [Y|L], [Y|R]) :- 
       remove_same_indicator(X, L, R).

Let's give it a try:

?- remove_same_indicator(a(_), [a(1),a(2),a(3),b(1)], R).
R = [b(1)]

Advantage over findall solution, one does not loose variables. For example one can do:

?- remove_same_indicator(a(_), [a(A),a(B),a(C),b(A)], R).
R = [b(A)]

But with the findall solution we get:

?- L=[a(A),a(B),a(C),b(A)], findall(X, (member(X,L),\+ (X = a(_))), R).
L = [a(A), a(B), a(C), b(A)],
R = [b(_I)]

The argument of b is not anymore bound to A, since findall creates copies and thus new variables.

Bye

functor/3 is ISO and also in Amzi!
http://www.amzi.com/manuals/amzi/pro/ref_manipulating_terms.htm#functorTermFunctorN

Answer 4

remove_all(_, [], []).
remove_all(X, [Y|R], L):- \+ X \= Y, remove_all(X, R, L).
remove_all(X, [Y|R], [Y|R2]):- X \= Y, remove_all(X, R2, L).