使用动态范围时Excel VBA错误

Question

I am tryin to fill a combobox (dragged onto my worksheet) with the values of a dynamic range.

Normaly 'ThisWorkbook.Names("NAME_OF_RANGE").RefersToRange' works, but it fails on my dynamic range!

I have tried a different solution (see code below), but then the worksheetname is stripped from the reference (and thus the wrong data is being filled)

Public Sub FillCombobox(cboComboBox As ComboBox, sRange As String)
'Remember current selected item
Dim sSelectedItem As String
sSelectedItem = cboComboBox.Text

'Empty the combobox
cboComboBox.Clear
cboComboBox.AddItem "---pick one---"

'Get the data from the dynamic range
Dim oListFillRange As Range
'This line will throw an error:
Set oListFillRange = ThisWorkbook.Names(sRange).RefersToRange 'Does not work with a dynamic range!!!
''Set oListFillRange = Range(Application.Evaluate(ThisWorkbook.Names(sRange).RefersTo).Address) 'Works with dynamic ranges on the SAME SHEET (as the sheetname is stripped out!)

'Fill combobox
Dim oRange As Range
For Each oRange In oListFillRange
    cboComboBox.AddItem oRange.Value
Next oRange

'Set previous selected item
Dim i As Integer
For i = 0 To cboComboBox.ListCount - 1
    If cboComboBox.List(i) = sSelectedItem Then
        cboComboBox.ListIndex = i
        Exit for
    End If
Next i

If cboComboBox.ListIndex = -1 Then cboComboBox.ListIndex = 0
End Sub

So how do I get 'ThisWorkbook.Names("NAME_OF_RANGE").RefersToRange' to work with dynamic ranges?

Answer 1

Refer to the range by the Range property.

Set oListFillRange = Sheets("mySheet").Range(sRange) 'where mySheet is the relevant sheet name

For some more information, the reason that RefersToRange does not work is because there is no range in the formula for dynamic ranges, so the excel properties cannot read the actual range. Therefore, referring to the range directly is the only way to go.