在Haskell的列表列表中替换元素

Question

I have a list of lists like so:

[["BBBBBBBB",
  "BWFFFPFGB", 
  "BWFFFPFGB",
  "BWFFMPFGB",
  "BWFFFPF_B",
  "BWFFFPF6B",
  "BBBBBBB"]]

I've done a little research and have found out how to access individual elements using the !! operator. But when it comes to searching for a certain element 'M' I'm not sure how to go about that. My friend said I need to use something like (x:xs):xss on a list, but when I try this in the WinGHCi haskell program I get this.

Prelude> let list =    [["BBBBBBBB",
  "BWFFFPFGB", 
  "BWFFFPFGB",
  "BWFFMPFGB",
  "BWFFFPF_B",
  "BWFFFPF6B",
  "BBBBBBB"]]


Prelude> head(x:xs):xss
<interactive>:192:2: Not in scope: `x'
<interactive>:192:4: Not in scope: `xs'
<interactive>:192:8: Not in scope: `xss'

I understand that I declare the name as list and not x:xs but even when I declare it as x:xs I still get the errors. I'm probably still a little new to haskell to really understand what to do so I may be going about this way wrong.

I've looked here Replace individual list elements in Haskell? because eventually I want to replace the M with something different but I'm not completely sure how I would implement that.

Any help/guidance is appreciated, thanks!

Answer 1

First of all, virtually all "variables" in Haskell are immutable, so there's no "changing a list", there are modified copies.

Second, you need to find an element by some criteria. To do that, you need to traverse a list. - This can be done using recursion. Filtering can be done using a function passed as an argument of your traversing function (this function must take an element and return a boolean value).

Try to put the above together and make your own function. Start with a type signature, it shows what you want to do: to take a list of Char (it's better to generalize to a generic type) and a function which possibly changes an element and return a modified list:

replaceFunc :: (Char -> Char) -> String -> String

Also, read http://www.haskell.org/haskellwiki/How_to_work_on_lists , there's a hint there how to apply some function to specific elements only.

Answer 2

First let's see how to replace a W with M

charWM :: Char -> Char
charWM 'W' = 'M'  -- If you see W, put M.
charWM x  =  x   -- If you see anything else, put it back as is.

You can rewrite that function how you like by adding other letter transformations.

Now let's make that work over a list. There's a great function map :: (a ->b) -> [a] -> [b] that lets you apply a function on every element on a list.

stringWM :: String -> String
stringWM xs = map charWM xs  -- do charWM to everything in xs.

For example stringWM "QWERTY WILL WIN" = "QMERTY MILL MIN"

Next we can do that to a list of lists:

lolWM :: [String] -> [String]
lolWM xss = map stringWM xss

( String is a type synonym for [Char] .)
Let's test that out in ghci:

*Main> list'
["BBBBBBBB","BWFFFPFGB","BWFFFPFGB","BWFFMPFGB","BWFFFPF_B","BWFFFPF6B","BBBBBBB"]
*Main> lolWM list'
["BBBBBBBB","BMFFFPFGB","BMFFFPFGB","BMFFMPFGB","BMFFFPF_B","BMFFFPF6B","BBBBBBB"]

All good.

Your example wasn't exactly list' , it was [list'] which has 1 element, so to work on that we'd need to map lolWM . Often we wouldn't bother writing stringWM or lolWM and go directly to lists of lists of lists, if that's what we needed:

lololWM = (map.map.map) charWM

map.map.map means map the map of the map. You can allow that to blow your mind a little, or you can just say list of list of list of Char, so map map map - one map per list level.

---

In the future, maybe you'll want to replace W with Strings instead of characters.

rewriteChar :: Char -> String
rewriteChar 'W' = "--^--"
rewriteChar  x  = [x] -- put x in a list to make it a string

This time, map isn't enough: map rewriteChar "QWERTY WILL WIN" gives

["Q","--^--","E","R","T","Y"," ","--^--","I","L","L"," ","--^--","I","N"]

We could use concat on that to flatten it into a single list, but it's more fun to do

rewriteString = concatMap rewriteChar

So now rewriteString "QWERTY WILL WIN" give us "Q--^--ERTY --^--ILL --^--IN" .

For more mindblowing things to try, there's "QWERTY WILL WIN" >>= rewriteChar and "Hello Mum" >>= \\x -> [x,x,x]