Port hopping on IO::SOCKET::INET

Question

i am try to get a better understanding on Perl and was stumble about sockets. i am try to understand a "simple" example i found on xmodulo . I was expecting that like in the example the port will be 7777. But it seems like the port used for this socket communication is somewhere above 35000 and on every call of the client script the port is incremented by +1. Why ist the port different to the 7777 and why it is incrementing on every call?

the server example looks like this:

use IO::Socket::INET;     
# auto-flush on socket
$| = 1;     
# creating a listening socket
my $socket = new IO::Socket::INET (
    LocalHost => '0.0.0.0',
    LocalPort => '7777',
    Proto => 'tcp',
    Listen => 5,
    Reuse => 1
);
die "cannot create socket $!\n" unless $socket;
print "server waiting for client connection on port 7777\n";

while(1)
{
    # waiting for a new client connection
    my $client_socket = $socket->accept();

    # get information about a newly connected client
    my $client_address = $client_socket->peerhost();
    my $client_port = $client_socket->peerport();
    print "connection from $client_address:$client_port\n";

    # read up to 1024 characters from the connected client
    my $data = "";
    $client_socket->recv($data, 1024);
    print "received data: $data\n";

    # write response data to the connected client
    $data = "ok";
    $client_socket->send($data);

    # notify client that response has been sent
    shutdown($client_socket, 1);
}

$socket->close();

the client example is:

use IO::Socket::INET;     
# auto-flush on socket
$| = 1;

# create a connecting socket
my $socket = new IO::Socket::INET (
    PeerHost => '192.168.1.10',
    PeerPort => '7777',
    Proto => 'tcp',
);
die "cannot connect to the server $!\n" unless $socket;
print "connected to the server\n";

# data to send to a server
my $req = 'hello world';
my $size = $socket->send($req);
print "sent data of length $size\n";

# notify server that request has been sent
shutdown($socket, 1);

# receive a response of up to 1024 characters from server
my $response = "";
$socket->recv($response, 1024);
print "received response: $response\n";

$socket->close();   

Answer 1

A connection isn't defined by

• local address
• peer address
• port

It's defined by

• local address
• local port
• peer address
• peer port

For example,

>netstat /a

Active Connections

  Proto  Local Address          Foreign Address        State
  ...
  TCP    10.0.0.2:34208         stackoverflow:http     ESTABLISHED
  TCP    10.0.0.2:34212         stackoverflow:http     ESTABLISHED
  TCP    10.0.0.2:34213         stackoverflow:http     ESTABLISHED
  TCP    10.0.0.2:34224         stackoverflow:http     ESTABLISHED
  TCP    10.0.0.2:34226         stackoverflow:http     ESTABLISHED
  TCP    10.0.0.2:34227         stackoverflow:http     ESTABLISHED
  ...

You didn't specify a local port for the client, so the system picked an available one. That's the right thing to do. There's no reason to limit the client to one port. It can even cause problems.

For example, let's say your web browser tried to bind its sockets to port 80 (the port on which web servers listen ). Your web browser would only be able to have one request pending at a time. That would be bad. You want to be able to create multiple connections to the same service. This allows you to request two different images at the same time, this allows you to load two pages in two different tabs at the same time, and so on. In the example above, my machine had six connections to stackoverflow.com's port 80, but that wouldn't have been possible if the web browser has bound the socket to port 80.