Can I set an environment variable with the SVN revision number of a project?

Question

I am trying to get the revision number of a project and save it into a variable. I know I can get the revision number by svnversion command but I'm not sure how I can store it. I am using regular windows command prompt. Basically I'm trying to do something like : set svnVersion= %svnversion% but I'm not sure how??

Answer 1

To set the output of variable to the output of svnversion in a batch file, you have to do this:

for /f "delims=" %%a in ('svnversion') do @set myvar=%%a

echo %myvar% 

---

Different approach: If you have TortoiseSVN you can also use SubWCRev.exe . See get the project revision number into my project? or Automatic SVN Revision Numbering in ASP.Net MVC

Answer 2

If you need this from a remote repository (as in not checked out localy) you can do this

for /f "delims=: tokens=1,2" %%a in ('svn info %SVN_REPO_URL%') do (
  if "%%a"=="Revision" (
    set /a RELEASE_REVISION=%%b
  )
)

I use this in my release process to grab the revision number from a tag.

Answer 3

In bash (via Cygwin):

svn info | grep -i "Revision" | cut -d ' ' -f 2

You can then use that in a bash shell script to store the value in a variable.

Answer 4

“svn info”子命令将告诉您工作副本中的修订号。

Answer 5

Something like:

svn version > ver.txt
set /p ver= < ver.txt
del ver.txt
echo %ver%

Answer 6

Here is an alternative that uses a pipe to findstr to get a single line:

FOR /F "tokens=2" %%G IN ('svn info ^| findstr /B Revision:') DO SET SVN_REVISION=%%G
echo SVN_REVISION: %SVN_REVISION%

FOR /F "tokens=2" %%G IN ('svn info ^| findstr /B URL:') DO SET SVN_URL=%%G
echo SVN_URL: %SVN_URL%

Answer 7

查看是否有此帮助： 更改版本号