Update QueryTable and export result as txt file using (Excel VBA)

Question

I try to export single sheet as .txt file after refreshing querytable. I don't want to use Workbooks.Add or .Copy and .PasteSpecial method. So far, I've made this:

Do Until i = 5
  With Sheets(2).QueryTables(1)
     .Refresh BackgroundQuery:=False
  End With

  Sheets(2).SaveAs ThisWorkbook.path & filename & i & ".txt", _
  FileFormat:=xlTextMSDOS, CreateBackup:=False

i = i + 1
Loop

On first loop this works great, but on second i get errors.

Answer 1

Assuming Sheets(2) is part of ThisWorkbook , try the following:

Dim sep As String
sep = Application.PathSeparator

With ThisWorkbook
    Do Until i = 5
      .Sheets(2).QueryTables(1).Refresh BackgroundQuery:=False
      .Sheets(2).SaveAs .path & sep & filename & i & ".txt", _
           FileFormat:=xlTextMSDOS, CreateBackup:=False

      i = i + 1
    Loop
End With

Answer 2

Ok, I know what went wrong. Here is my original code:

Sub test()
Dim filename As String
Dim i As Integer
filename = "test_txt"
i = 0
Do Until i = 5
  With Sheets(2).QueryTables(1)
     .Refresh BackgroundQuery:=False
  End With

  Sheets(3).SaveAs ThisWorkbook.Path & "\FOLDER\" & filename & i & ".txt", _
  FileFormat:=xlTextMSDOS, CreateBackup:=False

i = i + 1
Loop
End Sub

Because i have ThisWorkbook.Path in loop, it changes every time I run it. Solution is simple - put ThisWorkbook.Path outsite the loop, like this:

Sub test()
Dim filename As String
Dim saveloc as String
Dim i As Integer
filename = "test_txt"
saveloc = ThisWorkbook.Path & "\FOLDER\"
i = 0
Do Until i = 5
  With Sheets(2).QueryTables(1)
     .Refresh BackgroundQuery:=False
  End With

  Sheets(3).SaveAs saveloc & filename & i & ".txt", _
  FileFormat:=xlTextMSDOS, CreateBackup:=False

i = i + 1
Loop
End Sub

Thanks @David Zemens for help!