Could not find com.android.support:support-annotations:26.1.0

Question

I have a project whose compileSdkVersion and targetSdkVersion is 25. When I tried to upgrade the version to 26, I got the following error:

Could not find com.android.support:support-annotations:26.1.0.
Required by:
    project :app
    project :app > com.android.support:support-compat:26.1.0

Please install the Android Support Repository from the Android SDK Manager.
Open Android SDK Manager

I opened Android SDK Manager, but could not find Android Support Repository to install.

How can I fix this problem?

Here's my app and project gradle files:

apply plugin: 'com.android.application'
apply plugin: 'com.neenbedankt.android-apt'
apply plugin: 'io.fabric'

android {
    compileSdkVersion 26
    buildToolsVersion '26.0.3'

    defaultConfig {
        //my default config
    }

    signingConfigs {
        config {
            //config
        }
    }

    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
            signingConfig signingConfigs.config
        }
        debug {
            versionNameSuffix ".debug"
        }
    }

    lintOptions {
        /*disable 'InvalidPackage'*/
        abortOnError false
    }

    repositories {
        jcenter()
        mavenCentral()
        maven { url 'https://maven.fabric.io/public' }
        maven { url "https://oss.sonatype.org/content/repositories/snapshots/" }
        maven { url "http://dl.bintray.com/populov/maven" }
        maven { url 'https://oss.sonatype.org/content/repositories/ksoap2-android-releases' }
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_7
        targetCompatibility JavaVersion.VERSION_1_7
    }
}

def support = '26.1.0'
def rounded_image_view = "2.3.0"

dependencies {
    compile fileTree(include: ['*.jar'], dir: 'libs')
    compile "com.android.support:support-annotations:$support"
    compile "com.android.support:appcompat-v7:$support"
    compile "com.android.support:support-v4:$support"
    compile "com.android.support:design:$support"
    compile "com.android.support:cardview-v7:$support"
    compile "com.android.support:recyclerview-v7:$support"
    compile "com.android.support:support-vector-drawable:$support"
    compile "com.android.support:support-compat:$support"
    compile "com.android.support:support-core-ui:$support"
    compile 'com.jakewharton:butterknife:7.0.1'
    compile 'com.wrapp.floatlabelededittext:library:0.0.6'
    /*compile 'javax.inject:javax.inject:1'*/

    //needed to resolve compilation errors, thanks to tutplus.org for finding the dependency
    compile 'com.michaelpardo:activeandroid:3.1.0-SNAPSHOT'
    compile 'com.balysv.materialmenu:material-menu:1.5.2'
    compile 'com.flyco.dialog:FlycoDialog_Lib:1.1.6@aar'
    compile 'com.flyco.animation:FlycoAnimation_Lib:1.0.0@aar'
    compile 'com.nhaarman.listviewanimations:lib-core:3.1.0@aar'
    compile 'com.nhaarman.listviewanimations:lib-manipulation:3.1.0@aar'
    compile 'com.nhaarman.listviewanimations:lib-core-slh:3.1.0@aar'
    compile 'com.norbsoft.typefacehelper:library:0.9.0'
    compile 'com.quinny898.library.persistentsearch:library:1.1.0-SNAPSHOT'
    compile 'com.rengwuxian.materialedittext:library:2.1.4'
    compile 'com.squareup.picasso:picasso:2.5.2'
    compile 'com.squareup.okhttp:okhttp:2.4.0'
    compile 'jp.wasabeef:picasso-transformations:2.1.0'
    compile 'com.tuenti.smsradar:library:1.0.4'
    compile 'com.viewpagerindicator:library:2.4.1@aar'
    compile 'com.xgc1986.android:parallaxpagertransformer:1.0.3'
    compile 'com.github.medyo:fancybuttons:1.5@aar'
    compile 'com.google.code.ksoap2-android:ksoap2-android:2.6.5'
    compile 'com.google.dagger:dagger:2.0.1'
    compile('com.github.afollestad.material-dialogs:core:0.8.5.3@aar') { transitive = true }
    compile 'com.google.android.gms:play-services-gcm:11.0.4'
    compile 'me.relex:circleindicator:1.2.2@aar'
    compile 'com.github.rubensousa:gravitysnaphelper:1.1'
    compile 'com.miguelcatalan:materialsearchview:1.4.0'
    compile 'com.makeramen:roundedimageview:2.3.0'
    compile 'com.journeyapps:zxing-android-embedded:3.5.0'
    compile('com.crashlytics.sdk.android:crashlytics:2.6.8@aar') {
        transitive = true;
    }
    compile 'com.github.bumptech.glide:glide:3.7.0'
    compile 'org.jsoup:jsoup:1.8.3'
    apt "com.google.dagger:dagger-compiler:2.0.1"
    provided 'org.glassfish:javax.annotation:10.0-b28'
    androidTestCompile(
            'org.mockito:mockito-core:1.9.5',
            'org.hamcrest:hamcrest-core:1.1',
            'org.hamcrest:hamcrest-integration:1.1',
            'org.hamcrest:hamcrest-library:1.1'
    )

    compile 'com.romandanylyk:pageindicatorview:0.2.0@aar'
    compile 'ca.barrenechea.header-decor:header-decor:0.2.8'
    compile "com.makeramen:roundedimageview:$rounded_image_view"
    compile 'cz.msebera.android:httpclient:4.4.1.2'
    compile 'de.hdodenhof:circleimageview:2.2.0'


}

apply plugin: 'com.google.gms.google-services'

And:

buildscript {
    repositories {
        jcenter()
        mavenCentral()
        maven { url 'https://maven.fabric.io/public' }
        maven { url "https://oss.sonatype.org/content/repositories/snapshots" }
    }

    dependencies {
        classpath 'com.android.tools.build:gradle:2.3.3'
        classpath 'com.google.gms:google-services:3.0.0'
        classpath 'com.neenbedankt.gradle.plugins:android-apt:1.4'
        classpath 'io.fabric.tools:gradle:1.22.1'
    }
}

allprojects {
    repositories {
        maven { url "http://dl.bintray.com/populov/maven" }
        maven { url "https://jitpack.io" }
        mavenCentral()
        jcenter()
    }

    gradle.projectsEvaluated {
        tasks.withType(JavaCompile) {
            options.compilerArgs << "-Xlint:unchecked" << "-Xlint:deprecation"
        }
    }
}

Answer 1

I answer my own question:

Adding maven { url 'https://maven.google.com' } to:

allprojects {
    repositories {
        ...
        maven { url 'https://maven.google.com' }//this line is added
        mavenCentral()
        jcenter()
    }
}

worked for me because my gradle version was 3.x . I think the answer of @shizhen is also correct but the gradle version should be changed to 4.x+ .

For more information refer to difference between google() and maven { url 'https://maven.google.com' }

Answer 2

Try to add " google() " repo inside your buildscripts block.

buildscript {
    repositories {
        google() // add this new line. 
        jcenter()
        mavenCentral()
        maven { url 'https://maven.fabric.io/public' }
        maven { url "https://oss.sonatype.org/content/repositories/snapshots" }
    }

    dependencies {
        //classpath 'com.android.tools.build:gradle:2.3.3'
        classpath 'com.android.tools.build:gradle:3.0.1' // change the gradle plugin version to 3.0.1.
        classpath 'com.google.gms:google-services:3.0.0'
        classpath 'com.neenbedankt.gradle.plugins:android-apt:1.4'
        classpath 'io.fabric.tools:gradle:1.22.1'
    }
}

Also, maybe change your gradle wrapper version to 4.1 inside gradle-wrapper.properties

distributionBase=GRADLE_USER_HOME
distributionPath=wrapper/dists
zipStoreBase=GRADLE_USER_HOME
zipStorePath=wrapper/dists
distributionUrl=https\://services.gradle.org/distributions/gradle-4.1-all.zip

If still have issue, try to install the later Android Studio 3.1.2.

Answer 3

Here is Android Support Repository in SDK Manager

Answer 4

应将google()作为第一个 repo并将Android Gradle Plugin版本升级到3.0.1

classpath 'com.android.tools.build:gradle:3.0.1'