VBA Excel Loop All Sheets

Question

My code below only works on sheet1 and doesn't loop through all worksheets.

Would anyone know why, please?

Sub DeleteValueRows()

    Dim Firstrow As Long
    Dim Lastrow2 As Long
    Dim Lrow As Long
    Dim ws As Worksheet

For Each ws In ThisWorkbook.Worksheets

        Firstrow = 1
        Lastrow2 = Cells(Rows.Count, "A").End(xlUp).Row
        For Lrow = Lastrow2 To Firstrow Step -1

            With Cells(Lrow, "A")
                If Not IsError(.Value) Then
                    If .Value = "0" Then .Value = ""

                End If
            End With
        Next Lrow
Next ws

End Sub

Answer 1

With feat. the 'Dot Issue'

Sub DeleteValueRows()

    Dim Firstrow As Long
    Dim Lastrow2 As Long
    Dim Lrow As Long
    Dim ws As Worksheet

    For Each ws In ThisWorkbook.Worksheets

        With ws

            Firstrow = 1
            Lastrow2 = .Cells(.Rows.Count, "A").End(xlUp).Row

            For Lrow = Lastrow2 To Firstrow Step -1

                With .Cells(Lrow, "A")
                    If Not IsError(.Value) Then
                        If .Value = "0" Then .Value = ""

                    End If
                End With

            Next Lrow

        End With

    Next ws

End Sub