How can I move the contents of one directory tree into another?

Question

I have a directory which contains files and a number of levels of subdirectories:

C:\Source

I would like to move the contents of C:\\Source into:

C:\Destination

Requirements:

• All files and all subdirectories within C:\\SourceData must be moved
• I will be running the command in a batch file
• I can't use Powershell or any other scripting languages

Attempt 0

XCOPY /E "C:\Source" "C:\Destination"

This works perfectly, but it copies instead of moves. I can't copy then delete the source as I'm moving a very large set of files and there isn't enough disk space to have two copies of them at a time.

Attempt 1

MOVE "C:\Source" "C:\Destination"

This moves the entire C:\\Source directory into C:\\Destination so I end up with:

C:\Destination\Source

Attempt 2

With some help from this question and accepted answer I came up with:

for /r "C:\Source" %%x in (*) do move "%%x" "C:\Destination"

This moves the files within C:\\Source but not the subdirectories or their contents. Note that I used %%x instead of %x as I'm using it in a batch file.

Using FOR seems promising but I'm not sure I've used the right syntax? Have I missed something?

Attempt 3

As suggested by Nick D, I tried rename:

RENAME "C:\\Source" Destination

For the example scenario I gave this works fine. Unfortunately my real Destination directory is at a different level to the Source directory and this doesn't seem to be supported:

C:\>REN /?
Renames a file or files.

RENAME [drive:][path]filename1 filename2.
REN [drive:][path]filename1 filename2.

Note that you cannot specify a new drive or path for your destination file.

I get "The syntax of the command is incorrect." errors if I try to specify a more complex destination path, for example:

RENAME "C:\Source" "C:\MyOtherDirectory\Destination"
RENAME "C:\Source" "MyOtherDirectory\Destination"

Answer 1

Undoubtedly use robocopy. It is a simple but brilliantly useful tool.

robocopy /move /e sourcedir destdir

This will move all the files and folders, including empty ones, deleting each original file after it has moved it.

If you don't have robocopy installed you can download it by itself or as part of a Microsoft resource kit.

Answer 2

Update :

Adjusted code to a. check whether folders already exist at the destination, in which case move files in that folder over (and continue traversing the source directory structure), otherwise move the folder wholesale.

At the end of the script the source folder is removed altogether to eliminate these folders which have had their files moved over to an already existent folder at the destination (meaning these folders have been emptied but not deleted at the source).

Additionally we check whether a folder is both empty and already exists at the destination in which case we do nothing (and leave the source folder to be deleted to the last line of the script). Not doing this results in "The filename, directory name, or volume label syntax is incorrect." errors.

Phew! Please let me know how you get on with this! I have tested this and it seems to be working well.

for /d /r "c:\source" %%i in (*) do if exist "c:\destination\%%~ni" (dir "%%i" | find "0 File(s)" > NUL & if errorlevel 1 move /y "%%i\*.*" "c:\destination\%%~ni") else (move /y "%%i" "c:\destination")
move /y c:\source\*.* c:\destination
rd /s /q c:\source  

Answer 3

由于XCOPY可以使用，你可以使用XCOPY和DELETE，这是一种解决方法，但应该有效吗？

Answer 4

on Vista use

robocopy source destination /MIR

/MIR .. mirror a complete directory tree (also deletes files in the destination)

else

xcopy

Of course you have to delete the source afterwards :)

Answer 5

I have a directory which contains files and a number of levels of subdirectories:

C:\\Source

I would like to move the contents of C:\\Source into:

C:\\Destination

Maybe I'm missing something, but can't you just rename the folder?

Answer 6

在推特上发送：尝试将尝试3与尝试1结合使用。重命名以使目标文件夹正确，然后将“目标”移动到正确的位置。

Answer 7

@echo on
set SOURCE=C:\Source
set DESTINATION=C:\Destination

xcopy %SOURCE%\* %DESTINATION%\* /s /e /i /Y

PAUSE

i use batch file like this...

or simply call:

xcopy C:\Source\* C:\Destination\* /s /e /i /Y

Answer 8

Maybe a little off-topic, but still usefull:

Some people suggest to just copy + delete the source files, but moving files is not the same as copying + deleting!

When using the (x)copy function, you allocate new space on the same volume on a harddisk. After the copying the files, the old files (the old allocated space which was required for the files) are beign marked as deleted . While you will achieve the same result as an end-user, moving does something diffrent and more efficient.

Moving files actually only changes some records in the MFT (master file table). These changes only consist of a different path for the user to locate its files. Physically the files still remain in the same sectors on the harddisk.

Answer 9

In response to ufukgun's answer:

xcopy C:\Source\* C:\Destination\* /s /e /i /Y

/s - Copies directories and subdirectories except empty ones.
/e - Copies directories and subdirectories, including empty ones. Same as /S /E. May be used to modify /T.
/i - If destination does not exist and copying more than one file, assumes that destination must be a directory.
/y - Suppresses prompting to confirm you want to overwrite an existing destination file.

As stated in another answer, using xcopy may be not as efficient as it would be a native move command that only changes pointers in the filesystem.

Answer 10

I use a utility called xxcopy. It can move files and have many useful options, you can use it like this :

xxcopy C:\Source C:\Destination /E /RC

the options :

• /E to copy everything even empty folders

• /RC to remove every source file after each successful copy

you can download free copy of xxcopy for personal use from : http://www.xxcopy.com/xcpydnld.htm

Answer 11

I leave this code I have written based on ljs's attempt, It moves directory trees as Windows does, overwriting the files that already exists in destination with those in source, and avoiding the slow copy and erase method except if the destination is in a different drive.

If your SO is not in english must change line 6 with the text used by the Dir command when it finds 0 files.

movedir.bat source_dir destination_dir

@echo off
SETLOCAL  ENABLEDELAYEDEXPANSION

if %1.==. echo movedir dir1[\*] dir2 & echo move dir1 inside dir2 overwriting coincident files & echo option \* moves only dir1 content & goto end

set S=%~f1
set D=%~f2
set "noFiles= 0 File"
set "R=0"         rem R is option [\*] flag

if %S:~-2%.==\.. set "S=%S:~,-2%" & set "R=1"

if not exist "%S%" goto paramERR
if not exist "%D%" goto paramERR

set "Trim=0" & set "Sc=%S%"
:LP
set /A Trim+=1 & (set "Sc=!Sc:~1!") & if NOT !Sc!.==. goto LP

if %R%==0 (if exist "%D%\%~n1%~x1" (set "D=%D%\%~n1%~x1")) else move /y "%S%" "%D%" & goto end

CALL:movefiles "%S%" "%D%"
for /D /R "%S%" %%I in (*) do (set "Way=%%~fI") & (set "Way=!Way:~%Trim%!") & if exist "%D%!Way!" (CALL:movefiles "%%I" "%D%!Way!") else (move /y "%%I" "%D%!Way!\.." > NUL)
rd /s/q "%S%" & if %R%==1 md "%S%"
goto end

:movefiles 
dir %1 | find "%noFiles%" > NUL & if ERRORLEVEL 1 move /y "%~1\*.*" %2 > NUL 
goto :eof

:paramERR
echo Source or Destination does not exist
:end

Answer 12

If all your trying to do is move a directory and the content up one level:

MOVE folder_you_wan_to_move ..

Note that .. refers to the next directory up.

Answer 13

I think the easiest thing you could do is to modify your Attempt 2

from

MOVE "C:\Source" "C:\Destination"

to

MOVE "C:\Source\*" "C:\Destination"

KISS ;-)

Edit : this seem not to work, so my advice is to trash away the crappy DOS command line and use Cygwin with BASH as a shell! (or just add the cygwin binaries to the path so you can use mv within DOS, thus not having to change the shell as your requirements state).