Sum of even in Scheme

Question

This is my first experience with Scheme. I have a list with integers and I wanna get the sum of all even number in list.

 ; sum_even
(define (sum_even l)
  (if (null? l) l
  (cond ((even? (car l)) 0)
        ((not(even? (car l))) (car l)))
  (+ (sum_even (car l) (sum_even(cdr l))))))
(sum_even '(2 3 4))

Answer 1

(define (sum_even l)
    (cond ((null? l) 0)
          ((even? (car l)) (+ (car l) (sum_even (cdr l))))
          (else (sum_even (cdr l)))))

Not tested

Answer 2

You're not exactly asking a question. Are you checking if your solution is correct or looking for an alternate solution?

You can also implement it as follows via

(apply + (filter even? lst))

edit: If, as you mentioned, you can't use filter, this solution will work and is tail-recursive:

(define (sum-even lst)
    (let loop ((only-evens lst) (sum 0))
        (cond
            ((null? only-evens) sum)             
            ((even? (car only-evens))
             (loop (cdr only-evens) (+ (car only-evens) sum)))
            (else (loop (cdr only-evens) sum)))))

Answer 3

(define (sum-even xs)
  (foldl (lambda (e acc) 
           (if (even? e) 
               (+ e acc) 
               acc))
         0 
         xs))

Example:

> (sum-even (list 1 2 3 4 5 6 6))
18

Answer 4

Here is another one with higher order functions and no explicit recursion:

(use srfi-1)

(define (sum-even ls) (fold + 0 (filter even? ls)))

Answer 5

Consider using the built-in filter function. For example:

(filter even? l)

will return a list of even numbers in the list l. There are lots of ways to sum numbers in a list (example taken from http://groups.engin.umd.umich.edu/CIS/course.des/cis400/scheme/listsum.htm ):

;
; List Sum
; By Jerry Smith
;
(define (list-sum lst)
   (cond
     ((null? lst)
       0)
     ((pair? (car lst))
      (+(list-sum (car lst)) (list-sum (cdr lst))))
     (else
       (+ (car lst) (list-sum (cdr lst))))))