Exporting data from excel to word on multiple columns

Question

Hi I am using the following code to copy values from an excel worksheet into a predefined table in word. The below works fine for 1 column, how can I get it to tranfer the data for all 5 columns? Thanks

Sub ExportData()

Dim wdApp As Word.Application
Dim wdDoc As Word.Document
Dim wdCell As Word.Cell
Dim i As Long
Dim wbBook As Workbook
Dim wsSheet As Worksheet
Dim rnData As Range
Dim vaData As Variant

Set wbBook = ThisWorkbook
Set wsSheet = wbBook.Worksheets("Sheet1")

With wsSheet
    Set rnData = .Range("A1:E10")
End With

'Add the values in the range to a one-dimensional variant-array.
vaData = rnData.Value

'Here we instantiate the new object.
Set wdApp = New Word.Application

'Here the target document resides in the same folder as the workbook.
Set wdDoc = wdApp.Documents.Open(ThisWorkbook.Path & "\Test.doc")

'Import data to the first table and in the first column of a table in Microsoft Word.
For Each wdCell In wdDoc.Tables(1).Columns(1).Cells
    i = i + 1
    wdCell.Range.Text = vaData(i, 1)
Next wdCell

'Save and close the document.
With wdDoc
    .Save
    .Close
End With

'Close the hidden instance of Microsoft Word.
wdApp.Quit

'Release the external variables from the memory
Set wdDoc = Nothing
Set wdApp = Nothing
MsgBox "The data has been transfered to Test.doc, vbInformation"

End Sub

Answer 1

So this is a bit of a late answer, but try the following:

Add to declarations

Dim j As Long

Remove from declarations

Dim rnData As Range

Change

With wsSheet
    Set rnData = .Range("A1:E10")
End With

'Add the values in the range to a one-dimensional variant-array.
vaData = rnData.Value

to

ReDim vaData(1 To 10, 1 To 5)

With wsSheet
    vaData = .Range("A1:E10")
End With

And change

'Import data to the first table and in the first column of a table in Microsoft Word.
For Each wdCell In wdDoc.Tables(1).Columns(1).Cells
    i = i + 1
    wdCell.Range.Text = vaData(i, 1)
Next wdCell

to

For j = 1 To 5
    i = 0

    For Each wdCell In wdDoc.Tables(1).Columns(j).Cells
        i = i + 1
        wdCell.Range.Text = vaData(i, j)
    Next wdCell

Next j

A correction

MsgBox "The data has been transferred to Test.doc", vbInformation